First commit

config/hybar/modules/ActiveWindow.qml

@@ -0,0 +1,37 @@
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Widgets
+import Quickshell.Hyprland
+import Quickshell
+
+Item {
+    implicitWidth: t.contentWidth + 10 
+    implicitHeight: 30
+
+    ClippingWrapperRectangle {
+        radius: 5
+        anchors.fill: parent
+        Text {
+            id: t
+            verticalAlignment: Text.AlignVCenter
+            horizontalAlignment: Text.AlignHCenter
+            text: {
+                if(hws.toplevels.values.length > 0) {
+                    return Hyprland.activeToplevel.title
+                } else {
+                    return "  Desktop"
+                }
+            }
+
+            property HyprlandWorkspace hws: Hyprland.focusedWorkspace
+
+            onHwsChanged: {
+                Hyprland.refreshToplevels()
+                Hyprland.refreshWorkspaces()
+            }
+
+            font.pointSize: 11
+        }
+    }
+}

config/hybar/modules/Bar.qml

@@ -0,0 +1,175 @@
+import Quickshell // for PanelWindow
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Io
+import Quickshell.Widgets
+import Quickshell.Wayland
+
+PanelWindow {
+    anchors {
+        top: true
+        left: true
+        right: true
+        //bottom: true
+
+    }
+
+    id: bar
+
+    exclusionMode: ExclusionMode.Auto
+    WlrLayershell.layer: WlrLayer.Background
+
+    color: Pywal.special.background
+
+    implicitHeight: 40
+    
+    margins {
+        left: 15
+        right: 15
+        top: 5
+    }
+
+
+    /*RowLayout {
+        width: bar.width
+    }*/
+    RowLayout {
+        //Layout.alignment: Qt.AlignLeft | Qt.AlignVCenter
+        id: left
+        x: 0
+        y: parent.y + (parent.height - height) / 2
+        //width: center.x
+        spacing: 0
+
+        Launcher { 
+            id: l 
+            Layout.alignment: Qt.AlignLeft | Qt.AlignVCenter
+            Layout.preferredWidth: width
+            Layout.margins: 5
+        }
+
+        Workspaces { 
+            id: ws 
+            Layout.alignment: Qt.AlignLeft | Qt.AlignVCenter
+            Layout.margins: 5
+        }
+
+        /*ActiveWindow {
+            id: aw
+            Layout.margins: 5
+
+            Layout.maximumWidth: Math.min(implicitWidth, center.x - (parent.x + x + Layout.margins))
+        }*/
+
+    }
+
+    RowLayout {
+        //Layout.alignment: Qt.AlignHCenter | Qt.AlignVCenter
+        id: center
+        x: (parent.width - cl.width) / 2 + parent.x - centerLeft.width
+        //y: parent.y + (parent.height - height) / 2
+        y: parent.y + (parent.height - height) / 2
+        spacing: 0
+
+        RowLayout {
+            id: centerLeft
+            spacing: 0
+            
+            Volume { 
+                id: v 
+                window: bar
+                popupOffset: center.x
+                Layout.margins: 5
+            }
+
+            Battery { 
+                id: bat 
+                window: bar
+                popupOffset: center.x
+                Layout.margins: 5
+            }
+
+            Hyprsunset { 
+                id: hs 
+                Layout.margins: 5
+            }
+        }
+
+
+        Clock { 
+            id: cl 
+            Layout.margins: 5
+        }
+
+        IdleInhibitor { 
+            id: ii 
+            Layout.margins: 5
+        }
+
+        Wifi { 
+            id: wifi 
+            window: bar
+            Layout.margins: 5
+        }
+
+        Bluetooth { 
+            id: bt 
+            window: bar
+            popupOffset: center.x + center.width
+            Layout.margins: 5
+        }
+
+    }
+
+
+    RowLayout {
+        //Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+        id: right
+        //implicitWidth: bar.width - (spacer.x + spacer.width)
+        x: bar.width - implicitWidth
+        y: parent.y + (parent.height - height) / 2
+        //Layout.maximumWidth: bar.width - (center.x + center.width)
+        //Layout.preferredWidth: 10
+        spacing: 0
+
+        Media { 
+            Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+            id: media
+            
+            implicitWidth: Math.min(textWidth, bar.width - (righter.width) - (center.x + center.width) - 10)
+
+            Layout.margins: 5
+        }
+
+        RowLayout {
+            id: righter
+            spacing: 0
+            Tray { 
+                id: tray
+                window: bar 
+                Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+                Layout.margins: 5
+                popupOffset: right.x + righter.x + x
+            }
+
+            Notifications { 
+                id: notif 
+                window: bar
+                Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+                Layout.margins: 5
+            }
+
+            Power { 
+                id: power 
+                window: bar
+                popupOffset: bar.width
+                Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+                Layout.margins: 5
+            }
+        }
+    }
+
+
+
+}

config/hybar/modules/Battery.qml

@@ -0,0 +1,95 @@
+import Quickshell // for PanelWindow
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Io
+import Quickshell.Widgets
+import Quickshell.Hyprland
+import Quickshell.Services.UPower
+
+ClippingWrapperRectangle {
+    radius: 5
+    width: 100; height: 30
+    color: "red"
+    Button {
+        id: button
+        text: if(UPower.onBattery) {
+            "󰁹 " + Math.floor(UPower.displayDevice.percentage * 100) + "%"
+        } else {
+            "󰂄 " + Math.floor(UPower.displayDevice.percentage * 100) + "%"
+        }
+        font.pointSize: 12
+        implicitHeight: parent.height
+        //icon.color: "red"
+        //icon.source: "/nix/store/c4dcn4vl0v5njv4d587sazrad1xgyd9h-rose-pine-icon-theme-unstable-2022-09-01/share/icons/rose-pine/symbolic/devices/battery-symbolic.svg"
+        onClicked: {
+            menu.visible = true
+            grab.active = true
+        }
+    }
+
+    required property var window
+    required property real popupOffset
+    id: root
+
+    PopupWindow {
+        
+        id: menu
+
+        anchor.window: window
+        anchor.rect.x: popupOffset
+        anchor.rect.y: 50
+        implicitWidth: 250
+        implicitHeight: 150
+        visible: false
+
+        color: "transparent"
+        
+        ClippingWrapperRectangle {
+            radius: 5
+
+            implicitHeight: parent.height - 20
+            implicitWidth: parent.width
+            
+            ColumnLayout {
+
+                spacing: 0
+
+                Button {
+                    Layout.topMargin: 5
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+
+                    text: 'performance'
+                    onClicked: PowerProfiles.profile = PowerProfile.Performance
+                    visible: PowerProfiles.hasPerformanceProfile
+                }
+                Button {
+                    Layout.topMargin: 5
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+
+                    text: 'balanced'
+                    onClicked: PowerProfiles.profile = PowerProfile.Balanced
+                }
+                Button {
+                    Layout.topMargin: 5
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+
+                    text: 'power saver'
+                    onClicked: PowerProfiles.profile = PowerProfile.PowerSaver
+                }
+            }
+        }
+
+        HyprlandFocusGrab {
+            id: grab
+            windows: [ menu ]
+            onCleared: menu.visible = false
+        }
+    }
+}

config/hybar/modules/Bluetooth.qml

@@ -0,0 +1,141 @@
+import Quickshell // for PanelWindow
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Io
+import Quickshell.Widgets
+import Quickshell.Hyprland
+import Quickshell.Bluetooth
+
+ClippingWrapperRectangle {
+    
+    
+    radius: 5
+    implicitWidth: 30; implicitHeight: 30
+    Button {
+        id: button
+        text: ""
+        font.pointSize: 16
+        
+        onClicked: {
+            menu.visible = true
+            grab.active = true
+        }
+        implicitHeight: parent.height
+    }
+
+    required property PanelWindow window
+    required property real popupOffset
+    id: root
+
+    PopupWindow {
+        
+        id: menu
+
+        anchor.window: window
+        anchor.rect.x: popupOffset - width
+        anchor.rect.y: 50
+        implicitWidth: 250
+        implicitHeight: 150
+        visible: false
+
+        color: "transparent"
+        
+        ClippingWrapperRectangle {
+            radius: 5
+
+            implicitHeight: parent.height - 20
+            implicitWidth: parent.width
+            
+            ColumnLayout {
+
+                spacing: 0
+
+                ClippingWrapperRectangle {
+                    radius: 5
+                    implicitWidth: parent.width - 2 * Layout.margins
+                    implicitHeight: 30
+                    Layout.alignment: Qt.AlignHCenter | Qt.AlignTop
+                    Layout.margins: 5
+                    color: "#ff3333aa"
+
+                    RowLayout {
+                        Text {
+                            text: 'Bluetooth'
+                            Layout.alignment: Qt.AlignLeft | Qt.AlignVCenter
+                            Layout.margins: 5
+                        }
+
+                        Switch {
+                            Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+                            //Layout.margins: 5
+                            checked: Bluetooth.defaultAdapter.enabled
+                            onClicked: Bluetooth.defaultAdapter.enabled = checked
+                        }
+                    }
+
+                }
+
+                ScrollView {
+                    Layout.alignment: Qt.AlignHCenter | Qt.AlignTop
+                    Layout.margins: 5
+
+                    implicitWidth: parent.width - 4 * Layout.margins
+                    implicitHeight: menu.height / 2
+
+                    id: scroll
+
+                    ColumnLayout {
+                        spacing: 0
+
+                        Repeater {
+
+                            id: rep
+
+                            model: Bluetooth.devices.values
+
+                            ClippingWrapperRectangle {
+                                radius: 5
+                                color: "#ff3333aa"
+
+                                implicitWidth: menu.width - 3 * scroll.x
+                                implicitHeight: 40
+                                
+                                Layout.alignment: Qt.AlignHCenter | Qt.AlignTop
+                                Layout.margins: 5
+
+                                RowLayout {
+                                    Text {
+                                        Layout.alignment: Qt.AlignLeft | Qt.AlignVCenter
+                                        Layout.margins: 5
+                                        
+                                        text: rep.model[index].name
+                                    }
+
+                                    Button {
+                                        Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+                                        Layout.rightMargin: 5
+                                        text: 'Connect'
+
+                                        onClicked: rep.model[index].connected = !rep.model[index].connected
+                                    }
+                                }
+
+
+                            }
+
+                        }
+                    }
+
+                }
+
+            }
+        }
+
+        HyprlandFocusGrab {
+            id: grab
+            windows: [ menu ]
+            onCleared: menu.visible = false
+        }
+    }
+}

config/hybar/modules/Clock.qml

@@ -0,0 +1,27 @@
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Widgets
+import Quickshell
+
+Item {
+    implicitWidth: t.contentWidth + 10 
+    implicitHeight: 30
+
+    ClippingWrapperRectangle {
+        radius: 5
+        anchors.fill: parent
+        Text {
+            id: t
+            verticalAlignment: Text.AlignVCenter
+            horizontalAlignment: Text.AlignHCenter
+            text: Qt.formatDateTime(clock.date, "dddd HH:mm:ss MM/dd/yyyy")
+            font.pointSize: 11
+
+            SystemClock {
+                id: clock
+                precision: SystemClock.Seconds
+            }
+        }
+    }
+}

config/hybar/modules/Hyprsunset.qml

@@ -0,0 +1,30 @@
+import Quickshell // for PanelWindow
+import QtQuick // for Text
+import QtQuick.Controls
+import Quickshell.Io
+import Quickshell.Widgets
+
+ClippingWrapperRectangle {
+    radius: 5
+    implicitWidth: 30; height: 30
+    Button {
+        id: button
+        text: "󰛨 "
+        font.pointSize: 16
+        Process {
+            id: idlent
+            running: false
+            command: ["hyprsunset", "-t", "4000"]
+
+            onExited: {
+                running = button.text == "󰛨 " ? false : true
+            }
+        }
+
+        onClicked: {
+            idlent.running = button.text == "󰛨 " ? true : false
+            button.text = button.text == "󰛨 " ? "󱩌 " : "󰛨 "
+        }
+        implicitHeight: parent.height
+    }
+}

config/hybar/modules/IdleInhibitor.qml

@@ -0,0 +1,34 @@
+import Quickshell // for PanelWindow
+import QtQuick // for Text
+import QtQuick.Controls
+import Quickshell.Io
+import Quickshell.Widgets
+
+ClippingWrapperRectangle {
+
+    property real interval: 100
+    id: root
+
+    radius: 5
+    implicitWidth: 30; height: 30
+    Button {
+        id: button
+        text: "󰒳 "
+        font.pointSize: 16
+        Process {
+            id: idlent
+            running: true
+            command: ["systemd-inhibit", "--what=idle", "sleep", root.interval.toString()]
+
+            onExited: {
+                running = button.text == "󰒲 " ? false : true
+            }
+        }
+
+        onClicked: {
+            idlent.running = button.text == "󰒲 " ? true : false
+            button.text = button.text == "󰒲 " ? "󰒳 " : "󰒲 "
+        }
+        implicitHeight: parent.height
+    }
+}

config/hybar/modules/Launcher.qml

@@ -0,0 +1,22 @@
+import Quickshell // for PanelWindow
+import QtQuick // for Text
+import QtQuick.Controls
+import Quickshell.Io
+import Quickshell.Widgets
+
+ClippingWrapperRectangle {
+    radius: 5
+    width: 30; height: 30
+    Button {
+        id: button
+        text: " "
+        font.pointSize: 16
+        Process {
+            id: launcher
+            running: false
+            command: ["rofi", "-show", "drun"]
+        }
+        onClicked: launcher.running = true
+        implicitHeight: parent.height
+    }
+}

config/hybar/modules/Media.qml

@@ -0,0 +1,48 @@
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Services.Mpris
+import Quickshell.Widgets
+
+Item {
+    id: media
+    height: 30
+
+    readonly property real textWidth: info.contentWidth + 10
+
+    ClippingWrapperRectangle {
+        radius: 5
+        anchors.fill: parent
+        Text {
+
+            verticalAlignment: Text.AlignVCenter
+            horizontalAlignment: Text.AlignHCenter
+
+            id: info
+
+            text: {
+                let s = ''
+                let players = []
+                
+                Mpris.players.values.forEach((p) => { 
+                    if(p.isPlaying) players.push(p)
+                })
+                
+                if(players[0]?.trackTitle) {
+                    s += players[0].trackTitle
+                }
+                if(players[0]?.trackAlbum) {
+                    s += ' - ' + players[0].trackAlbum
+                }
+                if(players[0]?.trackArtist) {
+                    s += ' - ' + players[0].trackArtist
+                }
+
+                media.visible = players.length > 0
+
+                return s
+            }
+            font.pointSize: 11
+        }
+    }
+}

config/hybar/modules/Notif.qml

@@ -0,0 +1,71 @@
+import Quickshell
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Services.Notifications
+import Quickshell.Io
+import Quickshell.Widgets
+import Quickshell.Hyprland
+
+ClippingWrapperRectangle {
+    id: notif
+    Layout.alignment: Qt.AlignHCenter | Qt.AlignTop
+    Layout.margins: 5
+    radius: 10
+    implicitWidth: parent.width - 2 * Layout.margins
+    implicitHeight: 100
+
+    color: Pywal.colors.color2
+
+    required property Notification src
+
+    MouseArea {
+        anchors.fill: parent
+
+        RowLayout {
+            Image {
+                //anchors.fill: parent
+                source: {
+                    console.log(notif.src)
+                    let icon = notif.src.image
+                    if (icon.includes("?path=")) {
+                        const [name, path] = icon.split("?path=");
+                        icon = Qt.resolvedUrl(`${path}/${name.slice(name.lastIndexOf("/") + 1)}`);
+                    }
+                    return icon
+                }
+
+                Layout.maximumWidth: 100
+                Layout.maximumHeight: 100
+            }
+
+            ColumnLayout {
+                Layout.topMargin: 10
+                Layout.alignment: Qt.AlignLeft | Qt.AlignTop
+                Text {
+                    color: Pywal.special.background
+                    Layout.alignment: Qt.AlignLeft | Qt.AlignTop
+                    text: notif.src.summary
+                    Layout.leftMargin: 10
+                    font.pointSize: 14
+                }
+                Text {
+                    color: Pywal.special.background
+                    Layout.alignment: Qt.AlignLeft | Qt.AlignVCenter
+                    text: notif.src.body
+                    Layout.leftMargin: 10
+                    font.pointSize: 12
+                }
+            }
+        }
+
+        acceptedButtons: Qt.LeftButton | Qt.RightButton
+
+        onClicked: mouse => {
+            if(mouse.button == Qt.LeftButton) {
+                notif.src.dismiss()
+            } else if(mouse.button == Qt.RightButton) {
+            }
+        }
+    }
+}

config/hybar/modules/Notifications.qml

@@ -0,0 +1,143 @@
+import Quickshell
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Services.Notifications
+import Quickshell.Io
+import Quickshell.Widgets
+import Quickshell.Hyprland
+
+Item {
+    width: 50
+    height: 30
+
+    ClippingWrapperRectangle {
+        id: barbutton
+        radius: 5
+        anchors.fill: parent
+        Button {
+            id: button
+            text: "󰂚"
+            font.pointSize: 16
+            
+            onClicked: {
+                
+
+                menu.visible = true
+                grab.active = true
+            }
+            implicitHeight: parent.height
+        }
+    }
+
+    NotificationServer {
+        id: server
+        persistenceSupported: true
+        imageSupported: true
+        actionsSupported: true
+        bodyImagesSupported: true
+        bodySupported: true
+        bodyHyperlinksSupported: true
+        inlineReplySupported: true
+        actionIconsSupported: true
+
+        onNotification: (n) => {
+            n.tracked = true
+        }
+
+
+    }
+
+    required property PanelWindow window
+    id: root
+
+    PopupWindow {
+        
+        id: menu
+
+        anchor.window: window
+        anchor.rect.x: window.width - width
+        anchor.rect.y: 50
+        implicitWidth: 400
+        implicitHeight: 1080 - anchor.rect.y
+        visible: false
+
+        color: "transparent"
+        
+        ClippingWrapperRectangle {
+            radius: 5
+            
+            color: Pywal.special.background
+
+            implicitHeight: parent.height - 20
+            implicitWidth: parent.width
+            
+            ColumnLayout {
+                id: lay
+
+                spacing: 10
+
+                ClippingWrapperRectangle {
+                    color: Pywal.colors.color2
+                    radius: 5
+                    Layout.margins: 5
+                    Layout.alignment: Qt.AlignVCenter | Qt.AlignTop
+                    implicitWidth: menu.width - 2 * Layout.margins
+                    
+                    RowLayout {
+                        width: parent.width
+                        Text {
+                            color: Pywal.colors.color0
+                            Layout.margins: 5
+                            Layout.alignment: Qt.AlignLeft | Qt.AlignVCenter
+                            text: 'Notifications'
+                        }
+                        Button {
+                            Layout.alignment: Qt.AlignRight | Qt.AlignVCenter
+                            Layout.margins: 5
+                            implicitWidth: 20
+                            implicitHeight: 20
+
+                            text: 'x'
+
+                            onClicked: {
+                                while(server.trackedNotifications.values.length > 0) {
+                                     server.trackedNotifications.values[0].dismiss()
+                                }
+                            }
+                        }
+                    }
+                }
+
+                ColumnLayout {
+                    Layout.alignment: Qt.AlignVCenter | Qt.AlignTop
+                    Repeater {
+                        id: rep
+
+                        model: server.trackedNotifications.values
+
+                        Notif {
+                            required property int index
+                            src: rep.model[index]
+                        }
+
+                        onItemAdded: (idx, it) => {
+                            button.text = '󱅫 ' + rep.count
+                        }
+
+                        onItemRemoved: (idx, it) => {
+                            button.text = (rep.count - 1) <= 0 ? "󰂚" : '󱅫 ' + (rep.count - 1)
+                        }
+                    }
+                }
+                
+            }
+        }
+
+        HyprlandFocusGrab {
+            id: grab
+            windows: [ menu ]
+            onCleared: menu.visible = false
+        }
+    }
+}

config/hybar/modules/Power.qml

@@ -0,0 +1,120 @@
+import Quickshell
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Hyprland
+import Quickshell.Io
+import Quickshell.Widgets
+
+Item {
+    width: 30
+    height: 30
+
+    id: root
+
+    required property PanelWindow window
+    required property real popupOffset
+
+    ClippingWrapperRectangle {
+        radius: 5
+        width: 30; height: 30
+        Button {
+            id: button
+            text: " "
+            font.pointSize: 16
+            
+            onClicked: {
+                menu.visible = true
+                grab.active = true
+            }
+            implicitHeight: parent.height
+        }
+    }
+
+    PopupWindow {
+        
+        id: menu
+
+        anchor.window: window
+        anchor.rect.x: popupOffset
+        anchor.rect.y: 50
+        implicitWidth: 150
+        implicitHeight: 250
+        visible: false
+
+        color: "transparent"
+        
+        ClippingWrapperRectangle {
+            radius: 5
+
+            implicitHeight: parent.height - 20
+            implicitWidth: parent.width
+            
+            ColumnLayout {
+
+                spacing: 0
+
+                Button {
+                    Layout.topMargin: 5
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+
+                    text: 'shutdown'
+                    onClicked: shutdown.running = true
+                    Process {
+                        id: shutdown
+                        running: false
+                        command: ["systemctl", "poweroff"]
+                    }
+                }
+                
+                Button {
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+                    text: 'reboot'
+                    onClicked: reboot.running = true
+                    Process {
+                        id: reboot
+                        running: false
+                        command: ["systemctl", "reboot"]
+                    }
+                }
+                
+                Button {
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+                    text: 'logout'
+                    onClicked: logout.running = true
+                    Process {
+                        id: logout
+                        running: false
+                        command: ["loginctl", "kill-session", "self" ]
+                    }
+                }
+                
+                Button {
+                    Layout.bottomMargin: 10
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+                    text: 'sleep'
+                    onClicked: sleep.running = true
+                    Process {
+                        id: sleep
+                        running: false
+                        command: ["systemctl", "sleep"]
+                    }
+                }
+            }
+        }
+
+        HyprlandFocusGrab {
+            id: grab
+            windows: [ menu ]
+            onCleared: menu.visible = false
+        }
+    }
+}

config/hybar/modules/Pywal.qml

@@ -0,0 +1,58 @@
+pragma Singleton
+
+import Quickshell
+import Quickshell.Io
+
+Singleton {
+
+    property string wallpaper: json.wallpaper
+
+    property string alpha: json.alpha
+
+    property JsonObject special: json.special
+    property JsonObject colors: json.colors
+
+    FileView {
+
+        path: "/home/nathan/.cache/wal/colors.json"
+
+        watchChanges: true
+
+        onFileChanged: reload()
+
+        JsonAdapter {
+            id: json
+            property string wallpaper: "/home/nathan/Pictures/Wallpaper/bluescape.jpg"
+
+            property string alpha: "100"
+
+            property JsonObject special: JsonObject {
+                property string background: "white"
+                property string foreground: "white"
+                property string cursor: "white"
+            }
+
+            property JsonObject colors: JsonObject {
+                property string color0: "white"
+                property string color1: "white"
+                property string color2: "white"
+                property string color3: "white"
+
+                property string color4: "white"
+                property string color5: "white"
+                property string color6: "white"
+                property string color7: "white"
+
+                property string color8: "white"
+                property string color9: "white"
+                property string color10: "white"
+                property string color11: "white"
+
+                property string color12: "white"
+                property string color13: "white"
+                property string color14: "white"
+                property string color15: "white"
+            }
+        }
+    }
+}

config/hybar/modules/Tray.qml

@@ -0,0 +1,62 @@
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Services.SystemTray
+import Quickshell.Widgets
+
+Item {
+    implicitWidth: 10 + rep.count * (2 * lay.spacing + 20)
+    height: 30
+    visible: SystemTray.items.values.length != 0
+
+    id: root
+    required property var window
+    required property real popupOffset
+
+    ClippingWrapperRectangle {
+        radius: 5
+        anchors.fill: parent
+        RowLayout {
+            id: lay
+            spacing: 4
+            Repeater {
+                id: rep
+
+                model: SystemTray.items
+                ClippingWrapperRectangle {
+                    Layout.alignment: Qt.AlignHCenter | Qt.AlignVCenter
+                    radius: 10
+                    implicitWidth: 20
+                    implicitHeight: 20
+                    MouseArea {
+                        anchors.fill: parent
+                        
+                        Image {
+                            anchors.fill: parent
+                            source: {
+                                let icon = SystemTray.items.values[index].icon
+                                if (icon.includes("?path=")) {
+                                    const [name, path] = icon.split("?path=");
+                                    icon = Qt.resolvedUrl(`${path}/${name.slice(name.lastIndexOf("/") + 1)}`);
+                                }
+                                return icon
+                            }
+                        }
+
+                        acceptedButtons: Qt.LeftButton | Qt.RightButton
+
+                        onClicked: (mouse) => {
+                            if(mouse.button == Qt.LeftButton) {
+                                SystemTray.items.values[index].activate()
+                            } else if(mouse.button == Qt.RightButton) {
+                                SystemTray.items.values[index].display(root.window, popupOffset, 40)
+                            }
+                        }
+                    }
+                }
+            }
+        }
+
+
+    }
+}

config/hybar/modules/Volume.qml

@@ -0,0 +1,107 @@
+import Quickshell // for PanelWindow
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Io
+import Quickshell.Widgets
+import Quickshell.Hyprland
+import Quickshell.Services.Pipewire
+
+ClippingWrapperRectangle {
+    radius: 5
+    width: 100; height: 30
+    Button {
+        id: button
+        text: (Pipewire.defaultAudioSink?.audio?.muted ? "   " : "   ") + Math.floor(Pipewire.defaultAudioSink?.audio?.volume * 100) + "%"
+        font.pointSize: 12
+        implicitHeight: parent.height
+
+        PwObjectTracker {
+            objects: [ Pipewire.defaultAudioSink ]
+        }
+
+        onClicked: {
+            menu.visible = true
+            grab.active = true
+        }
+
+    }
+
+    required property var window
+    required property real popupOffset
+    id: root
+
+    PopupWindow {
+        
+        id: menu
+
+        anchor.window: window
+        anchor.rect.x: popupOffset
+        anchor.rect.y: 50
+        implicitWidth: 250
+        implicitHeight: 150
+        visible: false
+
+        color: "transparent"
+        
+        ClippingWrapperRectangle {
+            radius: 5
+
+            implicitHeight: parent.height - 20
+            implicitWidth: parent.width
+
+            ScrollView {
+                ColumnLayout {
+
+                    spacing: 0
+
+                    Text {
+                        text: 'Output Devices'
+                    }
+
+                    ColumnLayout {
+                        Repeater {
+                            id: outputs
+
+                            model: {
+                                Pipewire.nodes.values.filter(n => n.isSink && n.audio && n.nickname != "")
+                            }
+
+                            Button {
+                                text: outputs.model[index].nickname
+                                onClicked: Pipewire.preferredDefaultAudioSink = outputs.model[index]
+                            }
+                        }
+                    }
+
+                    Text {
+                        text: 'Input Devices'
+                    }
+
+                    ColumnLayout {
+                        Repeater {
+                            id: inputs
+
+                            model: {
+                                Pipewire.nodes.values.filter(n => !n.isSink && n.audio && n.nickname != "")
+                            }
+
+                            Button {
+                                text: inputs.model[index].nickname
+                                onClicked: Pipewire.preferredDefaultAudioSource = inputs.model[index]
+                            }
+                        }
+                    }
+
+                }
+            }
+            
+        }
+
+        HyprlandFocusGrab {
+            id: grab
+            windows: [ menu ]
+            onCleared: menu.visible = false
+        }
+    }
+}

config/hybar/modules/Wifi.qml

@@ -0,0 +1,72 @@
+import Quickshell
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Hyprland
+import Quickshell.Io
+import Quickshell.Widgets
+
+Item {
+    implicitWidth: 30
+    implicitHeight: 30
+
+    ClippingWrapperRectangle {
+        radius: 5
+        anchors.fill: parent
+        Button {
+            id: button
+            text: "󰤨 "
+            font.pointSize: 16
+            
+            onClicked: {
+                menu.visible = true
+                grab.active = true
+            }
+            implicitHeight: parent.height
+        }
+    }
+
+    property var window: null
+    id: root
+
+    PopupWindow {
+        
+        id: menu
+
+        anchor.window: window
+        anchor.rect.x: root.parent.x + root.parent.width - width
+        anchor.rect.y: 50
+        implicitWidth: 250
+        implicitHeight: 150
+        visible: false
+
+        color: "transparent"
+        
+        ClippingWrapperRectangle {
+            radius: 5
+
+            implicitHeight: parent.height - 20
+            implicitWidth: parent.width
+            
+            ColumnLayout {
+
+                spacing: 0
+
+                Button {
+                    Layout.topMargin: 5
+                    x: (parent.width - width) / 2
+                    implicitWidth: parent.width - 10
+                    implicitHeight: parent.height / 5 - parent.spacing
+
+                    text: 'shutdown'
+                }
+            }
+        }
+
+        HyprlandFocusGrab {
+            id: grab
+            windows: [ menu ]
+            onCleared: menu.visible = false
+        }
+    }
+}

config/hybar/modules/Workspaces.qml

@@ -0,0 +1,47 @@
+import QtQuick // for Text
+import QtQuick.Controls
+import QtQuick.Layouts
+import Quickshell.Hyprland
+import Quickshell.Widgets
+
+Item {
+    implicitWidth: 10 + rep.count * (2 * lay.spacing + 25)
+    implicitHeight: 30
+
+    Component.onCompleted: Hyprland.refreshWorkspaces()
+
+    ClippingWrapperRectangle {
+        color: Pywal.colors.color2
+        radius: 5
+        anchors.fill: parent
+        RowLayout {
+            id: lay
+            Repeater {
+                id: rep
+
+                property var ws: {
+                    let arr = [];
+                    Hyprland.workspaces.values.forEach((w) => { if(w.id > 0) arr.push(w) })
+                    return arr;
+                }
+
+                model: ws
+                ClippingWrapperRectangle {
+                    Layout.alignment: Qt.AlignHCenter | Qt.AlignVCenter
+                    radius: 10
+                    implicitWidth: 25
+                    Button {
+                        background: Rectangle {
+                            color: Hyprland.focusedWorkspace.id == rep.model[index].id ? Pywal.colors.color6 : Pywal.colors.color4
+                            anchors.fill: parent
+                        }
+                        text: rep.model[index].id
+                        onClicked: rep.model[index].activate()
+                    }
+                }
+            }
+        }
+
+
+    }
+}