{ self, inputs, ... }: {

    imports = [
        inputs.home-manager.flakeModules.home-manager
    ];

    flake.homeModules.default = { config, lib, pkgs, ... }: {

        options.programs.aurora = with lib; {
            enable = mkEnableOption "aurora";

            package = mkPackageOption self.packages.${pkgs.stdenv.hostPlatform.system} "aurora" {
                default = [ "aurora" ];

                example = "aurora.packages.hybar";
            };

            systemd = {
                enable = mkEnableOption "aurora systemd unit";

                target = mkOption {
                    type = types.str;
                    default = "hyprland-session.target";
                };
            };
        };

        config = let
            cfg = config.programs.aurora;

            system = pkgs.stdenv.hostPlatform.system;
        in {

            programs.quickshell = {
                enable = cfg.enable;

                package = cfg.package;

                activeConfig = "aurora";

                configs = {
                    aurora = "${self.packages.${system}.aurora-dots}/share";
                    hybar = "${self.packages.${system}.hybar-dots}/share";
                };

                systemd = {
                    enable = cfg.systemd.enable;
                    target = cfg.systemd.target;
                };
            };
        };
    };
}