restructure

modules/users/nathan/home-manager/features/aurora.nix

@@ -0,0 +1,33 @@
+{ inputs, ... }: {
+
+    flake.homeModules.nathan = { config, lib, ... }: {
+
+        imports = [
+            inputs.aurora.homeModules.default
+        ];
+
+        options.homeconfig.aurora.enable = with lib; mkOption {
+            type = with types; bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.aurora.enable {
+
+            programs.aurora = {
+                enable = true;
+
+                systemd = {
+                    enable = true;
+                };
+
+                settings = {
+                    wallpaperDir = "${config.home.homeDirectory}/Pictures/Wallpaper";
+
+                    colorsPath = "${config.home.homeDirectory}/.cache/wal/colors.json";
+
+                    changeColorsCmd = "colorPrefix";
+                };
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/bash.nix

@@ -0,0 +1,35 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        home.packages = with pkgs; [ oh-my-posh ];
+
+        programs.bash = {
+            enable = true;
+            enableCompletion = true;
+
+            shellAliases = {
+                ls = "eza";
+                ll = "ls -l";
+
+                ksh = "kitten ssh";
+
+                v = "nvim";
+                vi = "nvim";
+                vim = "nvim";
+
+            };
+
+            bashrcExtra = ''
+                source ${pkgs.blesh}/share/blesh/ble.sh
+            '';
+
+            initExtra = if config.homeconfig.wal.enable then (lib.mkBefore ''
+                cat ${config.home.homeDirectory}/.cache/wal/sequences
+                eval "$(oh-my-posh init bash --config ${config.home.homeDirectory}/.cache/wal/ohmyposh.toml)"
+            '') else (lib.mkBefore ''
+                eval "$(oh-my-posh init bash --config ${config.home.homeDirectory}/.config/ohmyposh/ohmyposh.toml)"
+            '');
+        };
+    };
+}

modules/users/nathan/home-manager/features/bat.nix

@@ -0,0 +1,21 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        programs.bat = {
+
+            enable = true;
+
+            extraPackages = with pkgs.bat-extras; [
+                batman
+                    batpipe
+                    batgrep
+                    batdiff
+                    batwatch
+                    prettybat
+            ];
+
+
+        };
+    };
+}

modules/users/nathan/home-manager/features/calcurse.nix

@@ -0,0 +1,17 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options.homeconfig.calcurse.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.calcurse.enable {
+            home.packages = with pkgs; [
+                calcurse
+                    libnotify
+            ];
+        };
+    };
+}

modules/users/nathan/home-manager/features/eza.nix

@@ -0,0 +1,20 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        programs.eza = {
+
+            enable = true;
+
+            enableZshIntegration = true;
+
+            extraOptions = [
+                "--color=auto"
+            ];
+
+            git = true;
+
+            icons = "auto";
+        };
+    };
+}

modules/users/nathan/home-manager/features/firefox.nix

@@ -0,0 +1,63 @@
+{ inputs, ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options.homeconfig.firefox.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.firefox.enable {
+
+            home.sessionVariables.BROWSER = "${config.programs.firefox.package}/bin/firefox";
+
+            home.packages = lib.mkIf config.homeconfig.wal.enable [ 
+                pkgs.pywalfox-native
+            ];
+
+            home.file.".mozilla/native-messaging-hosts/pywalfox.json".text = let
+                pywalfox-wrapper = pkgs.writeShellScriptBin "pywalfox-wrapper" ''
+                ${pkgs.pywalfox-native}/bin/pywalfox start
+                '';
+            in lib.replaceStrings [ "<path>" ] [
+                "${pywalfox-wrapper}/bin/pywalfox-wrapper"
+            ] (lib.readFile "${pkgs.pywalfox-native}/lib/python3.13/site-packages/pywalfox/assets/manifest.json");
+
+
+            programs.firefox = {
+
+                enable = true;
+                package = pkgs.firefox;
+
+                profiles.nathan = {
+                    search = {
+                        default = "ddg";
+                        privateDefault = "ddg";
+                        force = true;
+                    };
+                    bookmarks = {
+                        force = true;
+                        settings = [
+                        {
+                            name = "toolbar";
+                            toolbar = true;
+                            bookmarks = [
+                            {
+                                name = "NixOS Search - Packages";
+                                url = "https://search.nixos.org/packages";
+                            }
+                            ];
+                        }
+                        ];
+                    };
+
+                    extensions.packages = with inputs.firefox-addons.packages.${pkgs.stdenv.hostPlatform.system}; [
+                        ublock-origin
+                            keepassxc-browser
+                            pywalfox
+                    ];
+                };
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/fzf.nix

@@ -0,0 +1,18 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        programs.fzf = {
+
+            enable = true;
+
+            enableZshIntegration = true;
+
+            tmux = {
+#enableShellIntegration = true;
+
+#shellIntegrationOptions = [];
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/git.nix

@@ -0,0 +1,50 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, ... }: {
+
+        options.homeconfig.git.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.git.enable {
+
+            sops = {
+                secrets = {
+                    "git/username" = {};
+                    "git/email" = {};
+                };
+
+                templates.gitconfig.content = ''
+                    [user]
+                    name = "${config.sops.placeholder."git/username"}"
+                    email = "${config.sops.placeholder."git/email"}"
+                '';
+            };
+
+            programs.git = {
+                enable = true;
+
+                includes = [
+                { path = "${config.sops.templates.gitconfig.path}"; }
+                ];
+
+                settings = {
+                    init = {
+                        defaultBranch = "master";
+                    };
+
+                    safe.directory = "/etc/nixos";
+
+                    url = {
+                        "ssh://gitea@gitea.esotericbytes.com/" = {
+                            insteadOf = [
+                                "server:"
+                            ];
+                        };
+                    };
+                };
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/hypridle.nix

@@ -0,0 +1,51 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options.homeconfig.hypridle.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.hypridle.enable {
+
+            services.hypridle = {
+                enable = true;
+
+                settings = {
+
+                    general = {
+                        lock_cmd = "aurora ipc call lockscreen lock"; 
+                            before_sleep_cmd = "loginctl lock-session";    # lock before suspend.
+                            after_sleep_cmd = "hyprctl --instance 0 dispatch dpms on";  # to avoid having to press a key twice to turn on the display.
+                    };
+
+                    listener = [
+
+                    {
+                        timeout = 150;                                # 2.5min.
+                            on-timeout = "brightnessctl -s set 10";        # set monitor backlight to minimum, avoid 0 on OLED monitor.
+                            on-resume = "brightnessctl -r";                 # monitor backlight restore.
+                    }
+
+                    {
+                        timeout = 300;                                 # 5min
+                            on-timeout = "loginctl lock-session";            # lock screen when timeout has passed
+                    }
+
+                    {
+                        timeout = 330;                                                     # 5.5min
+                            on-timeout = "hyprctl --instance 0 dispatch dpms off";                            # screen off when timeout has passed
+                            on-resume = "hyprctl --instance 0 dispatch dpms on && brightnessctl -r";          # screen on when activity is detected after timeout has fired.
+                    }
+
+                    {
+                        timeout = 1800;                                # 30min
+                            on-timeout = "systemctl suspend";                # suspend pc
+                    }
+                    ];
+                };
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/hyprland.nix

@@ -0,0 +1,50 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options.homeconfig.hyprland.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.hyprland.enable {
+
+            home.sessionVariables.NIX_OZONE_WL = "1";
+
+            programs.kitty.enable = lib.mkDefault true;
+
+            home.packages = with pkgs; [
+                pyprland
+            ];
+
+            home.activation.extraHyprFile = lib.hm.dag.entryAfter ["writeBoundary"] ''
+                if [[ ! -f ${config.home.homeDirectory}/.config/hypr/otf.conf ]]; then
+                    touch ${config.home.homeDirectory}/.config/hypr/otf.conf
+                fi
+            '';
+
+
+            wayland.windowManager.hyprland = {
+
+                enable = true;
+
+                package = null;
+                portalPackage = null;
+
+                systemd = {
+                    enable = true;
+                    variables = [ "--all" ];
+                };
+
+                extraConfig = ''
+                    bind = , Print, exec, grim -g "$(slurp)" > ~/Pictures/screenshots/$(date +"%m-%d-%Y_%H:%M:%S").png
+
+                    source = ${config.home.homeDirectory}/.config/hypr/main.conf
+
+                    exec-shutdown = if [[ -f ${config.home.homeDirectory}/.local/share/calcurse/.calcurse.pid ]]; then rm ${config.home.homeDirectory}/.local/share/calcurse/.calcurse.pid; fi
+                '';
+
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/kitty.nix

@@ -0,0 +1,38 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, ... }: {
+
+        programs.kitty = {
+
+            enable = true;
+
+            font = {
+                name = "FiraCode Nerd Font";
+                size = 12;
+            };
+
+            extraConfig = ''
+
+                confirm_os_window_close 0
+
+                include ${config.home.homeDirectory}/.cache/wal/colors-kitty.conf
+
+                disable_ligatures never
+
+                dynamic_background_opacity yes
+
+                tab_bar_edge top
+
+                map ctrl+shift+t new_tab
+                map ctrl+shift+w close_tab
+
+                map ctrl+tab next_tab
+                map ctrl+shift+tab previous_tab
+
+                allow_remote_control yes
+
+            '';
+        };
+    };
+}
+

modules/users/nathan/home-manager/features/mpd.nix

@@ -0,0 +1,44 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options = {
+            homeconfig.mpd.enable = lib.options.mkOption {
+                type = lib.types.bool;
+                default = false;
+            };
+        };
+
+        config = lib.mkIf config.homeconfig.mpd.enable {
+            services.mpd = {
+                enable = true;
+                network.startWhenNeeded = true;
+                network.port = 6600;
+                network.listenAddress = "127.0.0.1";
+                musicDirectory = "/home/nathan/Music";
+                extraConfig = ''
+                    audio_output {
+                        type "pipewire"
+                            name "Audio1"
+                    }
+                audio_output {
+                    type "fifo"
+                        name "visualizer"
+                        path "/tmp/mpd.fifo"
+                        format "44100:16:1"
+                }
+                '';
+            };
+
+            services.mpdris2 = { 
+                enable = true;
+                mpd.host = "127.0.0.1";
+                mpd.port = 6600;
+                package = pkgs.mpdris2;
+                mpd.musicDirectory = "/home/nathan/Music";
+                notifications = true;
+            };
+        };
+
+    };
+}

modules/users/nathan/home-manager/features/nh.nix

@@ -0,0 +1,25 @@
+{ inputs, ... }: {
+
+    flake.homeModules.nathan = { config, lib, ... }: {
+
+        options.homeconfig.nh.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.nh.enable {
+
+            programs.nh = {
+                enable = true;
+                package = let pkgs-us = import inputs.nixpkgs-us { system = "x86_64-linux"; }; in pkgs-us.nh;
+#flake = "${config.home.homeDirectory}/Projects/Olympus";
+
+                clean = {
+                    enable = true;
+                    dates = "weekly";
+                    extraArgs = "--keep 5 --keep-since 5d";
+                };
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/ohmyposh.nix

@@ -0,0 +1,146 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        home.packages = with pkgs; [
+            oh-my-posh
+        ];
+
+        programs.zsh = {
+
+            initContent = with lib; mkMerge [
+                (mkIf config.homeconfig.wal.enable (mkBefore ''
+                    cat ${config.home.homeDirectory}/.cache/wal/sequences
+                    eval "$(oh-my-posh init zsh --config ${config.home.homeDirectory}/.cache/wal/ohmyposh.toml)"
+                    
+                    function _colorRefresh() { 
+                        eval $(oh-my-posh init zsh --config ~/.cache/wal/ohmyposh.toml)
+                        zle accept-line
+                    }
+                    zle -N _colorRefresh
+                    bindkey '\r' _colorRefresh
+                ''))
+
+                (mkIf (!config.homeconfig.wal.enable) (mkBefore ''
+                    eval "$(oh-my-posh init zsh --config ${config.home.homeDirectory}/.config/ohmyposh/ohmyposh.toml)"
+                ''))
+            ];
+
+        };
+
+        home.file.".config/wal/templates/ohmyposh.toml".text = ''
+#:schema https://raw.githubusercontent.com/JanDeDobbeleer/oh-my-posh/main/themes/schema.json
+
+            version = 2
+            final_space = true
+            console_title_template = '{{{{ .Shell }}}} in {{{{ .Folder }}}}'
+
+            [[blocks]]
+            type = 'prompt'
+            alignment = 'left'
+            newline = true
+
+            [[blocks.segments]]
+            type = 'os'
+            style = 'diamond'
+            trailing_diamond = ''
+            background = 'p:c1'
+            foreground = 'p:c12'
+            template = ' {{{{ .Icon }}}} '
+
+            [[blocks.segments]]
+            type = 'session'
+            style = 'diamond'
+            trailing_diamond = ''
+            background = 'p:c2'
+            foreground = 'p:c14'
+            template = '{{{{ .UserName }}}}@{{{{ .HostName }}}}'
+
+            [[blocks.segments]]
+            type = 'path'
+            style = 'diamond'
+            trailing_diamond = ''
+            background = 'p:c4'
+            foreground = 'p:c13'
+            template = '{{{{ .Path }}}}'
+
+            [blocks.segments.properties]
+            style = 'full'
+
+            [[blocks]]
+            type = 'prompt'
+            overflow = 'hidden'
+            alignment = 'right'
+
+            [[blocks.segments]]
+            type = 'executiontime'
+            style = 'diamond'
+            leading_diamond = ''
+            background = 'p:c4'
+            foreground = 'p:c13'
+            template = '{{{{ .FormattedMs }}}}'
+
+            [[blocks.segments]]
+            type = 'time'
+            style = 'diamond'
+            leading_diamond = ''
+            background = 'p:c2'
+            foreground = 'p:c14'
+
+            [[blocks.segments]]
+            type = 'shell'
+            style = 'diamond'
+            leading_diamond = ''
+            background = 'p:c1'
+            foreground = 'p:c12'
+
+            [[blocks]]
+            type = 'prompt'
+            alignment = 'left'
+            newline = true
+
+            [[blocks.segments]]
+            type = 'text'
+            style = 'plain'
+            background = 'transparent'
+            foreground_templates = [
+            "{{{{ if gt .Code 0 }}}}p:c13{{{{end}}}}",
+            "{{{{ if eq .Code 0 }}}}p:c14{{{{end}}}}",
+            ]
+            template = "{{{{ if gt .Code 0 }}}}!❭ {{{{else}}}}❭ {{{{end}}}}"
+
+            [transient_prompt] 
+            foreground_templates = [
+                "{{{{ if gt .Code 0 }}}}p:c13{{{{end}}}}",
+                "{{{{ if eq .Code 0 }}}}p:c14{{{{end}}}}",
+            ]
+            background = 'transparent'
+            template = "{{{{ if gt .Code 0 }}}}!❭ {{{{else}}}}❭ {{{{end}}}}"
+
+            [secondary_prompt]
+            background = 'transparent'
+            forground = 'p:c14'
+            template = "❭❭ "
+
+
+            [palette]
+
+            c0 = "{color0}"
+            c1 = "{color1}"
+            c2 = "{color2}"
+            c3 = "{color3}"
+            c4 = "{color4}"
+            c5 = "{color5}"
+            c6 = "{color6}"
+            c7 = "{color7}"
+            c8 = "{color8}"
+            c9 = "{color9}"
+            c10 = "{color10}"
+            c11 = "{color11}"
+            c12 = "{color12}"
+            c13 = "{color13}"
+            c14 = "{color14}"
+            c15 = "{color15}"
+        '';
+    };
+}

modules/users/nathan/home-manager/features/opencode.nix

@@ -0,0 +1,54 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, ... }: {
+
+        options.homeconfig.opencode.enable = with lib; mkOption {
+            type = with types; bool;
+            default = true;
+        };
+
+        config = lib.mkIf config.homeconfig.opencode.enable {
+
+            programs.opencode = {
+                enable = true;
+
+                settings = {
+                    theme = "system";
+                    model = "ollama-remote/qwen3:8b";
+
+                    provider = {
+                        ollama-local = {
+                            name = "Ollama (local)";
+
+                            npm = "@ai-sdk/openai-compatible";
+
+                            options.baseURL = "http://localhost:11434/v1";
+
+                            models = {
+                                "ministral-3:8b".name = "Ministral 3 8B";
+                                "llama3.2".name = "Llama 3.2";
+                                "qwen3:8b".name = "Qwen 3";
+                            };
+
+                        };
+
+                        ollama-remote = {
+                            name = "Ollama (remote)";
+
+                            npm = "@ai-sdk/openai-compatible";
+
+                            options.baseURL = "https://ollama.esotericbytes.com/v1";
+
+                            models = {
+                                "ministral-3:8b".name = "Ministral 3 8B";
+                                "llama3.2".name = "Llama 3.2";
+                                "qwen3:8b".name = "Qwen 3";
+                            };
+
+                        };
+                    };
+                };
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/packages.nix

@@ -0,0 +1,117 @@
+{ inputs, ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: let 
+        system = pkgs.stdenv.hostPlatform;
+
+    pkgs-us = import inputs.nixpkgs-us {
+        inherit system;
+        config.allowUnfree = true;
+    };
+
+    in {
+
+        options.homeconfig.minimal = with lib; options.mkOption {
+            type = with types; bool;
+            default = false;
+        };
+
+        config = with lib; mkMerge [
+        {
+
+            home.packages = with pkgs; [
+
+                kjv
+                openssh
+                sops
+                dig
+                #toybox
+                btop
+                zip    
+                unzip
+                rsync
+                curl
+
+                (python314.withPackages (ps: with ps; [
+                    gpustat
+                    numpy
+                    matplotlib
+                    scipy
+                    pandas
+                    pyaudio
+                    pyusb
+                    requests
+                ]))
+            ];
+
+        }
+
+        (mkIf config.homeconfig.graphical {
+         home.packages = with pkgs; [
+
+         grim
+         slurp
+         wl-clipboard
+         xfce.thunar
+         blueberry
+         ];
+         })
+
+        (mkIf (!config.homeconfig.minimal) {
+         home.packages = with pkgs; [
+         cava 
+         android-tools
+         neovim-remote
+         zulu
+         fastfetch
+         ncmpcpp
+         playerctl
+         mpc
+         ffmpeg
+         ];
+         })
+
+        (mkIf (!config.homeconfig.minimal && config.homeconfig.graphical) {
+
+         nixpkgs.config = {
+         allowUnfree = true;
+         };
+
+         home.packages = with pkgs; [
+
+         handbrake
+         quickemu
+         bottles
+
+         brightnessctl
+         libdbusmenu-gtk3
+         lmms
+
+#unfree {
+         geogebra
+         spotify
+         discord
+#}
+         rustdesk-flutter
+         mpv
+         vlc
+         pavucontrol
+         rpi-imager
+         tigervnc
+         keepassxc
+         localsend
+
+#3D modeling/printing
+         blender
+         freecad-wayland
+         cura-appimage
+
+#productivity
+         libreoffice
+
+#games
+         prismlauncher
+         ];
+        })
+        ];
+    };
+}

modules/users/nathan/home-manager/features/pywal.nix

@@ -0,0 +1,22 @@
+{ inputs, ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options.homeconfig.wal.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.wal.enable {
+
+            home.packages = with pkgs; [
+                inputs.nixvim.packages.${pkgs.stdenv.hostPlatform.system}.pywal
+
+                    pywal16
+                    imagemagick
+            ];
+
+
+        };
+    };
+}

modules/users/nathan/home-manager/features/ripgrep.nix

@@ -0,0 +1,9 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { ... }: {
+
+        programs.ripgrep = {
+            enable = true;
+        };
+    };
+}

modules/users/nathan/home-manager/features/rofi.nix

@@ -0,0 +1,23 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options.homeconfig.rofi.enable = lib.options.mkOption {
+            type = lib.types.bool;
+            default = false;
+        };
+
+        config = lib.mkIf config.homeconfig.rofi.enable {
+            programs.rofi = {
+
+                enable = true;
+                package = pkgs.rofi;
+
+                cycle = true;
+
+                theme = "/home/nathan/.cache/wal/colors-rofi-dark.rasi";
+            };
+        };
+    };
+}
+

modules/users/nathan/home-manager/features/scripts.nix

@@ -0,0 +1,71 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        options = {
+            homeconfig.scripts.enable = lib.options.mkOption {
+                type = lib.types.bool;
+                default = true;
+            };
+        };
+
+        config = lib.mkMerge [
+
+        (lib.mkIf config.homeconfig.scripts.enable {
+         home.packages = [
+
+#scripts
+
+         (pkgs.writeShellScriptBin "randWallpaper" ''
+          file=''$(ls ${config.home.homeDirectory}/Pictures/Wallpaper/ | shuf -n 1)
+          aurora-set-wallpaper ${config.home.homeDirectory}/Pictures/Wallpaper/''$file
+          '')
+
+        (pkgs.writeShellScriptBin "colorPrefix" ''
+                   pidof firefox > /dev/null && ${pkgs.pywalfox-native}/bin/pywalfox update &
+                   pidof kitty > /dev/null && pkill -USR1 kitty
+                   pidof cava > /dev/null && pkill -USR1 cava
+                   for i in ''$(ls /run/user/1000 | grep nvim); do 
+                   ${pkgs.neovim-remote}/bin/nvr -s --servername /run/user/1000/''$i --remote-send '<cmd>colorscheme pywal<CR>'; 
+                   done
+
+                   eval "''$@"
+        '')
+
+                  (pkgs.writeShellScriptBin "onSystemStart" ''
+
+
+                   if [[ -f /tmp/aurora/tmp.jpg ]]; then
+                        hyprctl --batch "\
+                        dispatch exec aurora-init ;\
+                        dispatch exec aurora-set-wallpaper ;\
+                        dispatch exec ${pkgs.pyprland}/bin/pypr ;\
+                        dispatch exec ${pkgs.netbird-ui}/bin/netbird-ui ;\
+                        dispatch exec ${pkgs.hyprpolkitagent}/libexec/hyprpolkitagent ;\
+                        setcursor Bibata-Modern-Classic 16"
+                   else
+                        hyprctl --batch "\
+                        dispatch exec aurora-init ;\
+                        dispatch exec aurora-set-wallpaper ${config.home.homeDirectory}/Pictures/Wallpaper/bluescape.jpg ;\
+                        dispatch exec ${pkgs.pyprland}/bin/pypr ;\
+                        dispatch exec ${pkgs.netbird-ui}/bin/netbird-ui ;\
+                        dispatch exec ${pkgs.hyprpolkitagent}/libexec/hyprpolkitagent ;\
+                        setcursor Bibata-Modern-Classic 16"
+                   fi
+
+                   if [[ -f ${config.home.homeDirectory}/.local/share/calcurse/.calcurse.pid ]]; then
+                   rm ${config.home.homeDirectory}/.local/share/calcurse/.calcurse.pid
+                   fi
+
+                   sleep 3
+
+                   aurora ipc call shell reload
+                   hyprctl reload
+                   '')
+
+                   ];
+        })
+        ];
+    };
+}
+

modules/users/nathan/home-manager/features/ssh.nix

@@ -0,0 +1,27 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { ... }: {
+
+        programs.ssh = {
+
+            enable = true;
+
+# defaults as of 25.11
+            matchBlocks."*" = {
+                forwardAgent = false;
+                addKeysToAgent = "no";
+                compression = false;
+                serverAliveInterval = 0;
+                serverAliveCountMax = 3;
+                hashKnownHosts = false;
+                userKnownHostsFile = "~/.ssh/known_hosts";
+                controlMaster = "no";
+                controlPath = "~/.ssh/master-%r@%n:%p";
+                controlPersist = "no";
+            };
+            enableDefaultConfig = false;
+
+
+        };
+    };
+}

modules/users/nathan/home-manager/features/tmux.nix

@@ -0,0 +1,68 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { config, lib, pkgs, ... }: {
+
+        programs.tmux = {
+
+            enable = true;
+
+            clock24 = true;
+
+            mouse = true;
+
+            baseIndex = 0;
+
+            keyMode = "vi";
+
+            prefix = "C-b";
+
+            shell = "${pkgs.zsh}/bin/zsh";
+
+            extraConfig = ''
+                set -g status-position top
+
+                set -g @background '#0B0704'
+                set -g @foreground '#c2c1c0'
+                set -g @color0 '#0B0704'
+                set -g @color1 '#846550'
+                set -g @color2 '#4a526c'
+                set -g @color3 '#538281'
+                set -g @color4 '#7b8179'
+                set -g @color5 '#b4a589'
+                set -g @color6 '#78ada3'
+                set -g @color7 '#958d89'
+                set -g @color8 '#665b54'
+                set -g @color9 '#B1876B'
+                set -g @color10 '#636E90'
+                set -g @color11 '#6FAEAC'
+                set -g @color12 '#A5ADA2'
+                set -g @color13 '#F1DCB7'
+                set -g @color14 '#A1E7DA'
+                set -g @color15 '#c2c1c0'
+
+                set -g status-style 'fg=#0B0704,bg=#538281'
+                
+
+                set -g @p '#(pwd)'
+
+                set -g status-interval 1
+
+
+                set -g status-left-length 50
+                set -g status-left "#[fg=@color12,bg=@color1]  #[fg=@color1,bg=@color2]◤#[fg=@color14]#{user}@#H#[fg=@color2,bg=@color4]◤#[fg=@color2]#{s|/home/#{user}|~:@p}#[fg=@color4,bg=@background]◤"
+
+                set -g status-right "#[fg=@color2]◥#[fg=@color14,bg=@color2]%A %T#[fg=@color1]◥#[fg=@color12,bg=@color1]%D "
+
+                set -g window-status-separator '/'
+                set -g window-status-format '#[fg=@color3,bg=@color3]◢#[fg=@background,bg=@color3] #{window_index}: #{window_name} #[fg=@color3,bg=@color3]◤'
+                set -g window-status-current-format '#[fg=@color11,bg=@color3]◢#[fg=@background,bg=@color11,bold] #{window_index}: #{window_name} #[fg=@color11,bg=@color3]◤'
+
+                source ~/.cache/wal/colors-tmux.conf
+            '';
+
+        };
+
+    };
+}
+
+

modules/users/nathan/home-manager/features/yazi.nix

@@ -0,0 +1,10 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { ... }: {
+        config = {
+            programs.yazi = {
+                enable = true;
+            };
+        };
+    };
+}

modules/users/nathan/home-manager/features/zoxide.nix

@@ -0,0 +1,16 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { ... }: {
+
+        programs.zoxide = {
+
+            enable = true;
+
+            enableZshIntegration = true;
+
+            options = [
+                "--cmd cd"
+            ];
+        };
+    };
+}

modules/users/nathan/home-manager/features/zsh.nix

@@ -0,0 +1,40 @@
+{ ... }: {
+
+    flake.homeModules.nathan = { lib, ... }: {
+
+        programs.zsh = {
+
+            enable = true;
+
+            initContent = lib.mkOrder 1200 ''
+                bindkey ' ' magic-space
+            '';
+
+            enableCompletion = true;
+
+            autosuggestion.enable = true;
+
+            syntaxHighlighting.enable = true;
+
+            shellAliases = {
+                ls = "eza";
+                ll = "ls -l";
+
+                ksh = "kitten ssh";
+
+                vi = "nvim";
+                vim = "nvim";
+
+                python = "python3.14";
+                python3 = "python3.14";
+            };
+
+            history = {
+                size = 5000;
+                ignoreAllDups = true;
+                ignoreSpace = true;
+                share = true;
+            };
+        };
+    };
+}