reorganize and fix searxng

2026-01-20 17:30:56 -06:00
parent 50d192c809
commit 42bf08084e
86 changed files with 2863 additions and 35 deletions
--- a/homes/nathan/home-manager/default.nix
+++ b/homes/nathan/home-manager/default.nix
@@ -0,0 +1,109 @@
+{ config, lib, pkgs, inputs, ... }: {
+
+    imports = [
+        ./programs
+        ./services
+        ./packages
+        ./dotfiles
+	];
+
+    options.homeconfig = with lib; {
+
+        name = mkOption {
+            type = with types; nullOr str;
+            default = null;
+        };
+
+        graphical = mkOption {
+            type = with types; bool;
+            default = true;
+        };
+
+        standalone = mkOption {
+            type = with types; bool;
+            default = false;
+        };
+    };
+
+
+    config = {
+
+        homeconfig = {
+            name = "nathan";
+
+            mpd.enable = lib.mkDefault true;
+            calcurse.enable = lib.mkDefault true;
+            git.enable = lib.mkDefault true;
+            nh.enable = lib.mkDefault true;
+
+            minimal = lib.mkDefault false;
+            hyprland.enable = lib.mkDefault (config.homeconfig.graphical && !config.homeconfig.standalone);
+            hyprlock.enable = lib.mkDefault config.homeconfig.hyprland.enable;
+            wal.enable = lib.mkDefault config.homeconfig.graphical;
+            hyprpanel.enable = lib.mkDefault config.homeconfig.hyprland.enable;
+            rofi.enable = lib.mkDefault config.homeconfig.hyprland.enable;
+            firefox.enable = lib.mkDefault config.homeconfig.graphical;
+        };
+
+        home.username = lib.mkDefault config.homeconfig.name;
+
+        home.homeDirectory = lib.mkDefault "/home/${config.home.username}";
+
+        programs.home-manager.enable = config.homeconfig.standalone;
+
+        home.stateVersion = "23.11";
+
+        home.pointerCursor = lib.mkIf config.homeconfig.graphical {
+            gtk.enable = true;
+            package = pkgs.bibata-cursors;
+            name = "Bibata-Modern-Classic";
+            size = 16;
+        };
+
+        gtk = lib.mkIf (config.homeconfig.graphical && config.homeconfig.hyprland.enable) {
+            enable = true;
+            theme.name = "Tokyonight-Dark";
+            theme.package = pkgs.tokyonight-gtk-theme;
+            iconTheme.package = pkgs.rose-pine-icon-theme;
+            iconTheme.name = "rose-pine-moon";
+        };
+
+        sops = {
+            age.keyFile = "${config.home.homeDirectory}/.config/sops/age/keys.txt";
+            defaultSopsFile = ./secrets.yaml;
+            defaultSopsFormat = "yaml";
+        };
+
+        nix = lib.mkIf config.homeconfig.standalone {
+            nixPath = [ "nixpkgs=${inputs.nixpkgs}" ];
+            settings = {
+                experimental-features = [ "nix-command" "flakes" ];
+                builders = "ssh://builder x86_64-linux,aarch64-linux /run/secrets/remoteBuildKey 1 1 nixos-test,benchmark,big-parallel,kvm - -";
+                builders-use-substituters = true;
+            };
+        };
+
+        services.mpris-proxy.enable = true;
+
+        programs.ssh = {
+            enable = true;
+
+            matchBlocks = {
+                "builder" = {
+                    hostname = "blunkall.us";
+                    user = "remote-builder";
+                    identityFile = "${config.home.homeDirectory}/.ssh/id_ed25519";
+                    port = 2222;
+                };
+                
+                "remote" = {
+                    hostname = "blunkall.us";
+                    user = "nathan";
+                    identityFile = "${config.home.homeDirectory}/.ssh/id_ed25519";
+                    port = 2222;
+                };
+            };
+        };
+
+    };
+}