niriswitcher: remove module

The upstream project has been archived.

.github/labeler.yml

@@ -660,7 +660,6 @@
           - modules/programs/fuzzel.nix
           - modules/programs/hyprlock.nix
           - modules/programs/kickoff.nix
-          - modules/programs/niriswitcher.nix
           - modules/programs/onagre.nix
           - modules/programs/sway-easyfocus.nix
           - modules/programs/swaylock.nix

modules/deprecations.nix

@@ -1,6 +1,11 @@
 { lib, ... }:
 {
   imports = [
+    (lib.mkRemovedOptionModule [ "programs" "niriswitcher" "enable" ] ''
+      The niriswitcher module has been removed because the upstream project
+      has been archived.
+    '')
+
     (lib.mkRemovedOptionModule [ "programs" "glab" "enable" ] ''
       The glab module has been removed because changes are needed upstream to
       support mixing declarative and stateful configurations. See #8066.

modules/lib/maintainers.nix

@@ -517,12 +517,6 @@
     github = "silmarp";
     githubId = 67292496;
   };
-  vortriz = {
-    name = "Rishi Vora";
-    email = "vorarishi22+nix@gmail.com";
-    github = "Vortriz";
-    githubId = 97402159;
-  };
   zorrobert = {
     name = "zorrobert";
     email = "118135271+zorrobert@users.noreply.github.com";

modules/programs/niriswitcher.nix

@@ -1,88 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  ...
-}:
-let
-  cfg = config.programs.niriswitcher;
-
-  settingsFormat = pkgs.formats.toml { };
-in
-{
-  meta.maintainers = [ lib.hm.maintainers.vortriz ];
-
-  options.programs.niriswitcher = {
-    enable = lib.mkEnableOption "niriswitcher, an application switcher for niri";
-
-    package = lib.mkPackageOption pkgs "niriswitcher" { nullable = true; };
-
-    settings = lib.mkOption {
-      type = lib.types.nullOr settingsFormat.type;
-      default = null;
-      example = lib.literalExpression ''
-        {
-          keys = {
-            modifier = "Super";
-            switch = {
-              next = "Tab";
-              prev = "Shift+Tab";
-            };
-          };
-          center_on_focus = true;
-          appearance = {
-            system_theme = "dark";
-            icon_size = 64;
-          };
-        }
-      '';
-      description = ''
-        niriswitcher configuration.
-        For available settings see <https://github.com/isaksamsten/niriswitcher/?tab=readme-ov-file#options>.
-      '';
-    };
-
-    style = lib.mkOption {
-      type = with lib.types; nullOr (either path lines);
-      default = null;
-      example = ''
-        .application-name {
-          opacity: 1;
-          color: rgba(255, 255, 255, 0.6);
-        }
-        .application.selected .application-name {
-          color: rgba(255, 255, 255, 1);
-        }
-      '';
-      description = ''
-        CSS style of the switcher.
-        <https://github.com/isaksamsten/niriswitcher/?tab=readme-ov-file#themes>
-        for the documentation.
-
-        If the value is set to a path literal, then the path will be used as the CSS file.
-      '';
-    };
-  };
-
-  config = lib.mkIf cfg.enable {
-    assertions = [
-      (lib.hm.assertions.assertPlatform "programs.niriswitcher" pkgs lib.platforms.linux)
-    ];
-
-    home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
-
-    xdg.configFile = {
-      "niriswitcher/config.toml" = lib.mkIf (cfg.settings != null) {
-        source = settingsFormat.generate "config.toml" cfg.settings;
-      };
-
-      "niriswitcher/style.css" = lib.mkIf (cfg.style != null) {
-        source =
-          if builtins.isPath cfg.style || lib.isStorePath cfg.style then
-            cfg.style
-          else
-            pkgs.writeText "niriswitcher/style.css" cfg.style;
-      };
-    };
-  };
-}

tests/modules/programs/niriswitcher/default.nix

@@ -1,4 +0,0 @@
-{ lib, pkgs, ... }:
-lib.optionalAttrs pkgs.stdenv.hostPlatform.isLinux {
-  niriswitcher-program = ./niriswitcher.nix;
-}

tests/modules/programs/niriswitcher/expected.toml

@@ -1,12 +0,0 @@
-center_on_focus = true
-
-[appearance]
-icon_size = 64
-system_theme = "dark"
-
-[keys]
-modifier = "Super"
-
-[keys.switch]
-next = "Tab"
-prev = "Shift+Tab"

tests/modules/programs/niriswitcher/niriswitcher.nix

@@ -1,30 +0,0 @@
-{
-  programs.niriswitcher = {
-    enable = true;
-
-    settings = {
-      center_on_focus = true;
-      keys = {
-        modifier = "Super";
-        switch = {
-          next = "Tab";
-          prev = "Shift+Tab";
-        };
-      };
-      appearance = {
-        system_theme = "dark";
-        icon_size = 64;
-      };
-    };
-
-    style = ./style.css;
-  };
-
-  nmt.script = ''
-    assertFileExists home-files/.config/niriswitcher/config.toml
-    assertFileContent home-files/.config/niriswitcher/config.toml ${./expected.toml}
-
-    assertFileExists home-files/.config/niriswitcher/style.css
-    assertFileContent home-files/.config/niriswitcher/style.css ${./style.css}
-  '';
-}

tests/modules/programs/niriswitcher/style.css

@@ -1,7 +0,0 @@
-.application-name {
-  opacity: 1;
-  color: rgba(255, 255, 255, 0.6);
-}
-.application.selected .application-name {
-  color: rgba(255, 255, 255, 1);
-}