mirror of
https://github.com/nix-community/home-manager.git
synced 2026-06-05 21:02:51 +00:00
01ea51d706
This change converts redundant attribute assignments of the form `a = a;` or `a = someSet.a;` into cleaner `inherit` statements. This reduces verbosity and follows common Nix style for bringing attributes into scope. Statix Codes: W03 (manual_inherit), W04 (manual_inherit_from) Also include statix and the rule in our configuration.
62 lines
1.3 KiB
Nix
62 lines
1.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
let
|
|
|
|
cfg = config.editorconfig;
|
|
|
|
iniFormat = pkgs.formats.ini { };
|
|
|
|
in
|
|
{
|
|
meta.maintainers = with lib.maintainers; [ loicreynier ];
|
|
|
|
options.editorconfig = {
|
|
enable = lib.mkEnableOption "EditorConfig home configuration file";
|
|
|
|
settings = lib.mkOption {
|
|
inherit (iniFormat) type;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to {file}`$HOME/.editorconfig`.
|
|
`root = true` is automatically added to the file,
|
|
it must not be added here.
|
|
See <https://editorconfig.org> for documentation.
|
|
'';
|
|
example = lib.literalExpression ''
|
|
{
|
|
"*" = {
|
|
charset = "utf-8";
|
|
end_of_line = "lf";
|
|
trim_trailing_whitespace = true;
|
|
insert_final_newline = true;
|
|
max_line_width = 78;
|
|
indent_style = "space";
|
|
indent_size = 4;
|
|
};
|
|
};
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf (cfg.enable && cfg.settings != { }) {
|
|
home.file.".editorconfig".text =
|
|
let
|
|
renderedSettings = lib.generators.toINIWithGlobalSection { } {
|
|
globalSection = {
|
|
root = true;
|
|
};
|
|
sections = cfg.settings;
|
|
};
|
|
in
|
|
''
|
|
# Generated by Home Manager
|
|
${renderedSettings}
|
|
'';
|
|
};
|
|
}
|