mirror of
https://github.com/nix-community/home-manager.git
synced 2026-06-05 21:02:51 +00:00
01ea51d706
This change converts redundant attribute assignments of the form `a = a;` or `a = someSet.a;` into cleaner `inherit` statements. This reduces verbosity and follows common Nix style for bringing attributes into scope. Statix Codes: W03 (manual_inherit), W04 (manual_inherit_from) Also include statix and the rule in our configuration.
61 lines
1.4 KiB
Nix
61 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
pkgs,
|
|
config,
|
|
...
|
|
}:
|
|
let
|
|
tomlFormat = pkgs.formats.toml { };
|
|
cfg = config.programs.nix-init;
|
|
in
|
|
{
|
|
meta.maintainers = [ lib.maintainers.da157 ];
|
|
|
|
options.programs.nix-init = {
|
|
enable = lib.mkEnableOption "nix-init";
|
|
package = lib.mkPackageOption pkgs "nix-init" { nullable = true; };
|
|
settings = lib.mkOption {
|
|
inherit (tomlFormat) type;
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
maintainers = [
|
|
"figsoda"
|
|
];
|
|
nixpkgs = "<nixpkgs>";
|
|
commit = true;
|
|
access-tokens = {
|
|
"github.com" = "ghp_blahblahblah...";
|
|
"gitlab.com" = {
|
|
command = [
|
|
"secret-tool"
|
|
"or"
|
|
"whatever"
|
|
"you"
|
|
"use"
|
|
];
|
|
};
|
|
"gitlab.gnome.org" = {
|
|
file = "/path/to/api/token";
|
|
};
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/nix-init/config.toml`.
|
|
See <https://github.com/nix-community/nix-init#configuration> for the full list
|
|
of options.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
|
|
|
|
xdg.configFile."nix-init/config.toml" = lib.mkIf (cfg.settings != { }) {
|
|
source = tomlFormat.generate "config.toml" cfg.settings;
|
|
};
|
|
};
|
|
}
|