mirror of
https://github.com/nix-community/home-manager.git
synced 2026-06-05 21:02:51 +00:00
01ea51d706
This change converts redundant attribute assignments of the form `a = a;` or `a = someSet.a;` into cleaner `inherit` statements. This reduces verbosity and follows common Nix style for bringing attributes into scope. Statix Codes: W03 (manual_inherit), W04 (manual_inherit_from) Also include statix and the rule in our configuration.
59 lines
1.3 KiB
Nix
59 lines
1.3 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
|
|
cfg = config.programs.bottom;
|
|
|
|
tomlFormat = pkgs.formats.toml { };
|
|
|
|
in
|
|
{
|
|
meta.maintainers = [ ];
|
|
|
|
options = {
|
|
programs.bottom = {
|
|
enable = lib.mkEnableOption ''
|
|
bottom, a cross-platform graphical process/system monitor with a
|
|
customizable interface'';
|
|
|
|
package = lib.mkPackageOption pkgs "bottom" { nullable = true; };
|
|
|
|
settings = lib.mkOption {
|
|
inherit (tomlFormat) type;
|
|
default = { };
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/bottom/bottom.toml`.
|
|
|
|
See <https://github.com/ClementTsang/bottom/blob/master/sample_configs/default_config.toml>
|
|
for the default configuration.
|
|
'';
|
|
example = lib.literalExpression ''
|
|
{
|
|
flags = {
|
|
avg_cpu = true;
|
|
temperature_type = "c";
|
|
};
|
|
|
|
colors = {
|
|
low_battery_color = "red";
|
|
};
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
|
|
|
|
xdg.configFile."bottom/bottom.toml" = lib.mkIf (cfg.settings != { }) {
|
|
source = tomlFormat.generate "bottom.toml" cfg.settings;
|
|
};
|
|
};
|
|
}
|