mirror of
https://github.com/nix-community/home-manager.git
synced 2026-06-05 21:02:51 +00:00
01ea51d706
This change converts redundant attribute assignments of the form `a = a;` or `a = someSet.a;` into cleaner `inherit` statements. This reduces verbosity and follows common Nix style for bringing attributes into scope. Statix Codes: W03 (manual_inherit), W04 (manual_inherit_from) Also include statix and the rule in our configuration.
47 lines
1.0 KiB
Nix
47 lines
1.0 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.programs.git-cliff;
|
|
tomlFormat = pkgs.formats.toml { };
|
|
in
|
|
{
|
|
meta.maintainers = [ lib.hm.maintainers.NateCox ];
|
|
|
|
options.programs.git-cliff = {
|
|
enable = lib.mkEnableOption "git-cliff changelog generator";
|
|
|
|
package = lib.mkPackageOption pkgs "git-cliff" { nullable = true; };
|
|
|
|
settings = lib.mkOption {
|
|
inherit (tomlFormat) type;
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
header = "Changelog";
|
|
trim = true;
|
|
}
|
|
'';
|
|
description = ''
|
|
Configuration written to
|
|
{file}`$XDG_CONFIG_HOME/git-cliff/cliff.toml`. See
|
|
<https://git-cliff.org/docs/configuration>
|
|
for the documentation.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
|
|
|
|
xdg.configFile = {
|
|
"git-cliff/cliff.toml" = lib.mkIf (cfg.settings != { }) {
|
|
source = tomlFormat.generate "git-cliff-config" cfg.settings;
|
|
};
|
|
};
|
|
};
|
|
}
|