mirror of
https://github.com/nix-community/home-manager.git
synced 2026-06-05 21:02:51 +00:00
01ea51d706
This change converts redundant attribute assignments of the form `a = a;` or `a = someSet.a;` into cleaner `inherit` statements. This reduces verbosity and follows common Nix style for bringing attributes into scope. Statix Codes: W03 (manual_inherit), W04 (manual_inherit_from) Also include statix and the rule in our configuration.
61 lines
1.4 KiB
Nix
61 lines
1.4 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
let
|
|
|
|
cfg = config.programs.neovide;
|
|
settingsFormat = pkgs.formats.toml { };
|
|
|
|
in
|
|
{
|
|
meta.maintainers = [ lib.hm.maintainers.NitroSniper ];
|
|
|
|
options.programs.neovide = {
|
|
enable = lib.mkEnableOption "Neovide, No Nonsense Neovim Client in Rust";
|
|
|
|
package = lib.mkPackageOption pkgs "neovide" { nullable = true; };
|
|
|
|
settings = lib.mkOption {
|
|
inherit (settingsFormat) type;
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
fork = false;
|
|
frame = "full";
|
|
idle = true;
|
|
maximized = false;
|
|
neovim-bin = "/usr/bin/nvim";
|
|
no-multigrid = false;
|
|
srgb = false;
|
|
tabs = true;
|
|
theme = "auto";
|
|
title-hidden = true;
|
|
vsync = true;
|
|
wsl = false;
|
|
|
|
font = {
|
|
normal = [];
|
|
size = 14.0;
|
|
};
|
|
}
|
|
'';
|
|
description = ''
|
|
Neovide configuration.
|
|
For available settings see <https://neovide.dev/config-file.html>.
|
|
For any option not found will need to be done in your neovim's config instead.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
|
|
xdg.configFile."neovide/config.toml" = lib.mkIf (cfg.settings != { }) {
|
|
source = settingsFormat.generate "neovide-config.toml" cfg.settings;
|
|
};
|
|
};
|
|
}
|