From 91e4660ed8fc3e18b30172f7db4fcd87badeef7e Mon Sep 17 00:00:00 2001
From: Caleb Maclennan <caleb@alerque.com>
Date: Wed, 6 Nov 2024 18:23:08 +0300
Subject: [PATCH 1/2] git-warp-time: init at 0.8.4

---
 pkgs/by-name/gi/git-warp-time/package.nix | 78 +++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 pkgs/by-name/gi/git-warp-time/package.nix

diff --git a/pkgs/by-name/gi/git-warp-time/package.nix b/pkgs/by-name/gi/git-warp-time/package.nix
new file mode 100644
index 000000000000..02b58f2cf703
--- /dev/null
+++ b/pkgs/by-name/gi/git-warp-time/package.nix
@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+
+  # nativeBuildInputs
+  zstd,
+  pkg-config,
+  jq,
+  cargo,
+  rustc,
+  rustPlatform,
+
+  # buildInputs
+  libgit2,
+  typos,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "git-warp-time";
+  version = "0.8.4";
+
+  src = fetchurl {
+    url = "https://github.com/alerque/git-warp-time/releases/download/v${finalAttrs.version}/git-warp-time-${finalAttrs.version}.tar.zst";
+    sha256 = "sha256-Xh30nA77cJ7+UfKlIslnyD+93AtnQ+8P3sCFsG0DAUk=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    inherit (finalAttrs) src;
+    nativeBuildInputs = [ zstd ];
+    dontConfigure = true;
+    hash = "sha256-ozy8Mfl5fTJL2Sr22tCSnK30SOKaC9cL+g4lX6ivi9Q=";
+  };
+
+  nativeBuildInputs = [
+    zstd
+    pkg-config
+    jq
+    cargo
+    rustc
+    rustPlatform.cargoSetupHook
+  ];
+
+  buildInputs = [
+    libgit2
+    typos
+  ];
+
+  env = {
+    LIBGIT2_NO_VENDOR = "1";
+  };
+
+  outputs = [
+    "out"
+    "doc"
+    "man"
+    "dev"
+  ];
+
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "Utility to reset filesystem timestamps based on Git history";
+    longDescription = ''
+      A CLI utility that resets the timestamps of files in a Git repository
+      working directory to the exact timestamp of the last commit which
+      modified each file.
+    '';
+    homepage = "https://github.com/alerque/git-warp-time";
+    changelog = "https://github.com/alerque/git-warp-time/raw/v${finalAttrs.version}/CHANGELOG.md";
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [
+      alerque
+    ];
+    license = lib.licenses.gpl3Only;
+    mainProgram = "git-warp-time";
+  };
+})

From 635e9d2ebb5b1532b5e1541ee26f69a0f4be29a8 Mon Sep 17 00:00:00 2001
From: Doron Behar <doron.behar@gmail.com>
Date: Sat, 9 Nov 2024 18:24:14 +0200
Subject: [PATCH 2/2] sile: switch to the zstd based source

---
 pkgs/by-name/si/sile/package.nix | 11 +++++++----
 1 file changed, 7 insertions(+), 4 deletions(-)

diff --git a/pkgs/by-name/si/sile/package.nix b/pkgs/by-name/si/sile/package.nix
index 54a2317adf8d..db31c2e38323 100644
--- a/pkgs/by-name/si/sile/package.nix
+++ b/pkgs/by-name/si/sile/package.nix
@@ -1,9 +1,10 @@
 {
   lib,
   stdenv,
-  fetchzip,
+  fetchurl,
 
   # nativeBuildInputs
+  zstd,
   pkg-config,
   jq,
   cargo,
@@ -32,18 +33,20 @@ stdenv.mkDerivation (finalAttrs: {
   pname = "sile";
   version = "0.15.5";
 
-  src = fetchzip {
-    url = "https://github.com/sile-typesetter/sile/releases/download/v${finalAttrs.version}/sile-${finalAttrs.version}.zip";
-    sha256 = "sha256-zP+MGCXGEg19U6tMrHIdgAAfKQT21vFtmoEROXgxUB0=";
+  src = fetchurl {
+    url = "https://github.com/sile-typesetter/sile/releases/download/v${finalAttrs.version}/sile-${finalAttrs.version}.tar.zst";
+    sha256 = "sha256-0gE3sC0WMC0odnD9KFrSisO406+RZGCqa8jL/5Mhufk=";
   };
 
   cargoDeps = rustPlatform.fetchCargoTarball {
     inherit (finalAttrs) src;
+    nativeBuildInputs = [ zstd ];
     dontConfigure = true;
     hash = "sha256-hmgDG29C5JfQX2acMr8c3lmswa1u5XHauRWFd4QGmOo=";
   };
 
   nativeBuildInputs = [
+    zstd
     pkg-config
     jq
     cargo