From 58737ced61fa5bc8cf55a8824027f57878d94f76 Mon Sep 17 00:00:00 2001
From: Fabian Affolter <mail@fabian-affolter.ch>
Date: Tue, 29 Sep 2026 08:33:08 +0200
Subject: [PATCH] fluere: init at 0.8.1

Tool designed for network monitoring and analysis

https://github.com/SkuldNorniern/fluere
---
 pkgs/by-name/fl/fluere/package.nix | 58 ++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 pkgs/by-name/fl/fluere/package.nix

diff --git a/pkgs/by-name/fl/fluere/package.nix b/pkgs/by-name/fl/fluere/package.nix
new file mode 100644
index 000000000000..3798ca47a063
--- /dev/null
+++ b/pkgs/by-name/fl/fluere/package.nix
@@ -0,0 +1,58 @@
+{
+  lib,
+  fetchFromGitHub,
+  libgit2,
+  libpcap,
+  nix-update-script,
+  openssl,
+  pkg-config,
+  rustPlatform,
+  versionCheckHook,
+  zlib,
+  zstd,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "fluere";
+  version = "0.8.1";
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "SkuldNorniern";
+    repo = "fluere";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-311VCO+8xoWblt6zBOLd+7xmmBO7sE0KeUKO1Qwg9SI=";
+  };
+
+  cargoHash = "sha256-nMh4hO9kHCpE/+K1DNZT3UYe0iGUU6HRZUg00T6f+CM=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    libgit2
+    libpcap
+    openssl
+    zlib
+    zstd
+  ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  doInstallCheck = true;
+
+  env = {
+    LIBGIT2_NO_VENDOR = true;
+    ZSTD_SYS_USE_PKG_CONFIG = true;
+  };
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Tool designed for network monitoring and analysis";
+    homepage = "https://github.com/SkuldNorniern/fluere";
+    changelog = "https://github.com/SkuldNorniern/fluere/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ fab ];
+    mainProgram = "fluere";
+  };
+})