From 5895f7512cd7f6fc23a916a1d94fdbe36d67f414 Mon Sep 17 00:00:00 2001
From: AkosSeres <seresakos2000@gmail.com>
Date: Sat, 18 Jul 2026 23:19:06 +0200
Subject: [PATCH] middleclick: init at 3.2.0

---
 pkgs/by-name/mi/middleclick/package.nix | 52 +++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 pkgs/by-name/mi/middleclick/package.nix

diff --git a/pkgs/by-name/mi/middleclick/package.nix b/pkgs/by-name/mi/middleclick/package.nix
new file mode 100644
index 000000000000..0ab33594dc9a
--- /dev/null
+++ b/pkgs/by-name/mi/middleclick/package.nix
@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  nix-update-script,
+  unzip,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "middleclick";
+  version = "3.2.0";
+
+  __structuredAttrs = true;
+
+  src = fetchurl {
+    url = "https://github.com/artginzburg/MiddleClick/releases/download/${finalAttrs.version}/MiddleClick.zip";
+    hash = "sha256-6T8XYSp3QTxefO+UI/DcnbFm1m841B14OpkOLqa6aYw=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ unzip ];
+
+  dontUnpack = true;
+  dontBuild = true;
+
+  # Preserve the upstream Developer ID signature and notarized app bundle.
+  dontFixup = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p unpacked "$out/Applications"
+    unzip -q "$src" -d unpacked
+    mv unpacked/MiddleClick.app "$out/Applications/"
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Utility for emulating middle clicks with trackpad and Magic Mouse gestures";
+    homepage = "https://github.com/artginzburg/MiddleClick";
+    downloadPage = "https://github.com/artginzburg/MiddleClick/releases";
+    changelog = "https://github.com/artginzburg/MiddleClick/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ akosseres ];
+    platforms = lib.platforms.darwin;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+})