From ff9ad2338e219a44db42f77a10c9c2ff7f41b685 Mon Sep 17 00:00:00 2001
From: Fabian Affolter <mail@fabian-affolter.ch>
Date: Mon, 28 Sep 2026 17:10:53 +0200
Subject: [PATCH] hexora: init at 0.3.1

Static analysis of malicious Python code

https://github.com/rushter/hexora
---
 pkgs/by-name/he/hexora/package.nix | 62 ++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 pkgs/by-name/he/hexora/package.nix

diff --git a/pkgs/by-name/he/hexora/package.nix b/pkgs/by-name/he/hexora/package.nix
new file mode 100644
index 000000000000..e4ad7d16238c
--- /dev/null
+++ b/pkgs/by-name/he/hexora/package.nix
@@ -0,0 +1,62 @@
+{
+  lib,
+  cargo,
+  fetchFromGitHub,
+  nix-update-script,
+  pkg-config,
+  python3Packages,
+  rustc,
+  rustPlatform,
+  zstd,
+}:
+
+python3Packages.buildPythonApplication (finalAttrs: {
+  pname = "hexora";
+  version = "0.3.1";
+  pyproject = true;
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "rushter";
+    repo = "hexora";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-xBg8Rrtwgg8Obi7JOPwdRXwoQKL8skCY72vLJA/VPRk=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-Xc6CcJ6s8X7T04W2SP7XT2rKGh2TatkaCxP2sSUC+2Y=";
+  };
+
+  build-system = [
+    cargo
+    pkg-config
+    python3Packages.setuptools
+    python3Packages.setuptools-rust
+    python3Packages.wheel
+    rustPlatform.cargoSetupHook
+    rustc
+  ];
+
+  buildInputs = [ zstd ];
+
+  # Project has no tests
+  doCheck = false;
+
+  pythonImportsCheck = [ "hexora" ];
+
+  env = {
+    ZSTD_SYS_USE_PKG_CONFIG = true;
+  };
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Static analysis of malicious Python code";
+    homepage = "https://github.com/rushter/hexora";
+    changelog = "https://github.com/rushter/hexora/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ fab ];
+    mainProgram = "hexora";
+  };
+})