From 8b3e7893acb79a178eefcb03485e905ba1fd3a08 Mon Sep 17 00:00:00 2001
From: OPNA2608 <christoph.neidahl@gmail.com>
Date: Tue, 6 Jun 2023 14:50:58 +0200
Subject: [PATCH] lomiri.cmake-extras: init at unstable-2022-11-21

---
 pkgs/desktops/lomiri/default.nix              | 14 ++++++
 .../development/cmake-extras/default.nix      | 49 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 3 files changed, 65 insertions(+)
 create mode 100644 pkgs/desktops/lomiri/default.nix
 create mode 100644 pkgs/desktops/lomiri/development/cmake-extras/default.nix

diff --git a/pkgs/desktops/lomiri/default.nix b/pkgs/desktops/lomiri/default.nix
new file mode 100644
index 000000000000..bfeed045f9bd
--- /dev/null
+++ b/pkgs/desktops/lomiri/default.nix
@@ -0,0 +1,14 @@
+{ lib
+, pkgs
+, libsForQt5
+}:
+
+let
+  packages = self: let
+    inherit (self) callPackage;
+  in {
+    #### Development tools / libraries
+    cmake-extras = callPackage ./development/cmake-extras { };
+  };
+in
+  lib.makeScope libsForQt5.newScope packages
diff --git a/pkgs/desktops/lomiri/development/cmake-extras/default.nix b/pkgs/desktops/lomiri/development/cmake-extras/default.nix
new file mode 100644
index 000000000000..ee5665cd668f
--- /dev/null
+++ b/pkgs/desktops/lomiri/development/cmake-extras/default.nix
@@ -0,0 +1,49 @@
+{ stdenvNoCC
+, lib
+, fetchFromGitLab
+, cmake
+, qtbase
+}:
+
+stdenvNoCC.mkDerivation {
+  pname = "cmake-extras";
+  version = "unstable-2022-11-21";
+
+  src = fetchFromGitLab {
+    owner = "ubports";
+    repo = "development/core/cmake-extras";
+    rev = "99aab4514ee182cb7a94821b4b51e4d8cb9a82ef";
+    hash = "sha256-axj5QxgDrHy0HiZkfrbm22hVvSCKkWFoQC8MdQMm9tg=";
+  };
+
+  postPatch = ''
+    # We have nothing to build here, no need to depend on a C compiler
+    substituteInPlace CMakeLists.txt \
+      --replace 'project(cmake-extras)' 'project(cmake-extras NONE)'
+
+    # This is in a function that reverse dependencies use to determine where to install their files to
+    substituteInPlace src/QmlPlugins/QmlPluginsConfig.cmake \
+      --replace "\''${CMAKE_INSTALL_LIBDIR}/qt5/qml" "\''${CMAKE_INSTALL_PREFIX}/${qtbase.qtQmlPrefix}"
+  '';
+
+  strictDeps = true;
+
+  # Produces no binaries
+  dontWrapQtApps = true;
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    qtbase
+  ];
+
+  meta = with lib; {
+    description = "A collection of add-ons for the CMake build tool";
+    homepage = "https://gitlab.com/ubports/development/core/cmake-extras/";
+    license = licenses.gpl3Only;
+    maintainers = teams.lomiri.members;
+    platforms = platforms.all;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index e08e59367e72..d8ee8e0d78e9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -37582,6 +37582,8 @@ with pkgs;
 
   gnustep = recurseIntoAttrs (callPackage ../desktops/gnustep { });
 
+  lomiri = recurseIntoAttrs (callPackage ../desktops/lomiri { });
+
   lumina = recurseIntoAttrs (callPackage ../desktops/lumina { });
 
   ### DESKTOPS/LXDE