From a63a609103451ca140147cd9ce5402db40159128 Mon Sep 17 00:00:00 2001
From: Santhosh Raju <santhosh.raju@gmail.com>
Date: Tue, 11 Aug 2026 15:37:54 +0200
Subject: [PATCH] yopass: init at 14.9.0

---
 pkgs/by-name/yo/yopass/package.nix | 57 ++++++++++++++++++++++++++++++
 pkgs/by-name/yo/yopass/website.nix | 35 ++++++++++++++++++
 2 files changed, 92 insertions(+)
 create mode 100644 pkgs/by-name/yo/yopass/package.nix
 create mode 100644 pkgs/by-name/yo/yopass/website.nix

diff --git a/pkgs/by-name/yo/yopass/package.nix b/pkgs/by-name/yo/yopass/package.nix
new file mode 100644
index 000000000000..f6da068b784d
--- /dev/null
+++ b/pkgs/by-name/yo/yopass/package.nix
@@ -0,0 +1,57 @@
+{
+  buildGoModule,
+  callPackage,
+  fetchFromGitHub,
+  makeBinaryWrapper,
+  lib,
+}:
+let
+  version = "14.9.0";
+  src = fetchFromGitHub {
+    owner = "jhaals";
+    repo = "yopass";
+    tag = version;
+    hash = "sha256-YZeSGcQcAsOmIwhhVpGN7bxlNGsWIJNAwUBxJM/7314=";
+  };
+
+  website = callPackage ./website.nix { inherit src version; };
+in
+buildGoModule (finalAttrs: {
+  inherit version src;
+  pname = "yopass";
+
+  __structuredAttrs = true;
+  strictDeps = true;
+
+  vendorHash = "sha256-mR17QPGZNJ9Vx6y6mExvZDKReVxdUif8aQ6VMfKVgcM=";
+
+  nativeBuildInputs = [ makeBinaryWrapper ];
+
+  subPackages = [
+    "cmd/yopass"
+    "cmd/yopass-server"
+  ];
+
+  checkFlags = [
+    # Disable tests that require network access
+    "-skip=TestSecretNotFoundError"
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/yopass-server \
+      --add-flags "--asset-path ${website}"
+  '';
+
+  meta = {
+    description = "Secure sharing of secrets, passwords and files";
+    homepage = "https://github.com/jhaals/yopass";
+    changelog = "https://github.com/jhaals/yopass/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      ivarmedi
+      fraggerfox
+    ];
+    mainProgram = "yopass";
+    platforms = lib.platforms.unix;
+  };
+})
diff --git a/pkgs/by-name/yo/yopass/website.nix b/pkgs/by-name/yo/yopass/website.nix
new file mode 100644
index 000000000000..fc80fba3a76c
--- /dev/null
+++ b/pkgs/by-name/yo/yopass/website.nix
@@ -0,0 +1,35 @@
+{
+  fetchYarnDeps,
+  nodejs-slim,
+  src,
+  stdenv,
+  version,
+  yarnBuildHook,
+  yarnConfigHook,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "yopass-website";
+  inherit version;
+
+  src = src + "/website";
+
+  yarnOfflineCache = fetchYarnDeps {
+    yarnLock = "${finalAttrs.src}/yarn.lock";
+    hash = "sha256-x3ouozoDreaeeqoh8osXOqEYphy6vTalLMjQt5vowkg=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    nodejs-slim
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mv dist $out
+
+    runHook postInstall
+  '';
+})