From abc0e6b746c14bad685dfafdaccc5aed74c8a64d Mon Sep 17 00:00:00 2001
From: "Jeffrey C. Ollie" <jeff@ocjtech.us>
Date: Mon, 20 Jul 2026 11:51:07 -0500
Subject: [PATCH] netbox_4_6.plugins.netbox-qrcode: init at 0.0.21

---
 .../plugins/netbox-qrcode/package.nix         | 66 +++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 pkgs/by-name/ne/netbox_4_6/plugins/netbox-qrcode/package.nix

diff --git a/pkgs/by-name/ne/netbox_4_6/plugins/netbox-qrcode/package.nix b/pkgs/by-name/ne/netbox_4_6/plugins/netbox-qrcode/package.nix
new file mode 100644
index 000000000000..c43388e2513d
--- /dev/null
+++ b/pkgs/by-name/ne/netbox_4_6/plugins/netbox-qrcode/package.nix
@@ -0,0 +1,66 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  setuptools,
+
+  # dependencies
+  pillow,
+  qrcode,
+  psycopg2,
+
+  # nativeCheckInputs
+  django,
+  netaddr,
+  netbox,
+  python,
+}:
+
+buildPythonPackage (finalAttrs: {
+  __structuredAttrs = true;
+
+  pname = "netbox-qrcode";
+  version = "0.0.21";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "netbox-community";
+    repo = "netbox-qrcode";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-A4qjpbfTULzS0UchUN9eX8jZmwoX/ej/18L/YAB8dKA=";
+  };
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    qrcode
+    pillow
+  ];
+
+  nativeCheckInputs = [
+    django
+    netaddr
+    netbox
+    psycopg2 # not specified in pyproject.toml, but required at import time
+  ];
+
+  preFixup = ''
+    export PYTHONPATH=${netbox}/opt/netbox/netbox:$PYTHONPATH
+  '';
+
+  dontUsePythonImportsCheck = python.pythonVersion != netbox.python.pythonVersion;
+  pythonImportsCheck = [ "netbox_qrcode" ];
+
+  passthru.pluginName = "netbox_qrcode";
+
+  meta = {
+    description = "Netbox plugin for generate QR codes for objects: Rack, Device, Cable";
+    homepage = "https://github.com/netbox-community/netbox-qrcode";
+    changelog = "https://github.com/netbox-community/netbox-qrcode/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.asl20;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ felbinger ];
+  };
+})