From 097bc92dee5a3acc370b19c4356fc8533891884d Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?=F0=9D=91=B7=F0=9D=92=89=F0=9D=92=8A=F0=9D=92=8D?=
 =?UTF-8?q?=F0=9D=92=90=F0=9D=92=84=F0=9D=92=82=F0=9D=92=8D=F0=9D=92=9A?=
 =?UTF-8?q?=F0=9D=92=94=F0=9D=92=95?= <regime_skylark.0y@icloud.com>
Date: Thu, 7 May 2026 14:41:34 -0400
Subject: [PATCH] lulu: init at 4.3.1

---
 pkgs/by-name/lu/lulu/package.nix | 52 ++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 pkgs/by-name/lu/lulu/package.nix

diff --git a/pkgs/by-name/lu/lulu/package.nix b/pkgs/by-name/lu/lulu/package.nix
new file mode 100644
index 000000000000..6dc2ddbcd8a8
--- /dev/null
+++ b/pkgs/by-name/lu/lulu/package.nix
@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  undmg,
+  nix-update-script,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "lulu";
+  version = "4.3.1";
+
+  __structuredAttrs = true;
+  strictDeps = true;
+
+  src = fetchurl {
+    url = "https://github.com/objective-see/LuLu/releases/download/v${finalAttrs.version}/LuLu_${finalAttrs.version}.dmg";
+    hash = "sha256-zANmUn8fQSMpX9EzKaCAMaZgr9JWB23asD5gdDZc75M=";
+  };
+
+  nativeBuildInputs = [ undmg ];
+
+  unpackPhase = ''
+    runHook preUnpack
+    undmg "$src"
+    runHook postUnpack
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/Applications"
+    cp -R LuLu.app "$out/Applications/LuLu.app"
+
+    runHook postInstall
+  '';
+
+  dontFixup = true; # Preserve upstream's notarized app bundle and system extension signature.
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Free open-source macOS firewall that alerts you to outgoing network connections";
+    homepage = "https://objective-see.org/products/lulu.html";
+    changelog = "https://github.com/objective-see/LuLu/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.gpl3Plus;
+    mainProgram = "LuLu";
+    maintainers = with lib.maintainers; [ philocalyst ];
+    platforms = lib.platforms.darwin;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+})