From f0f4299f1be4ae326efffbc47c1b43b4c028741d Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Sandro=20J=C3=A4ckel?= <sandro.jaeckel@gmail.com>
Date: Mon, 28 Sep 2026 13:14:04 +0200
Subject: [PATCH] awscurl: init at 0.44

---
 pkgs/by-name/aw/awscurl/package.nix | 51 +++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/aw/awscurl/package.nix

diff --git a/pkgs/by-name/aw/awscurl/package.nix b/pkgs/by-name/aw/awscurl/package.nix
new file mode 100644
index 000000000000..353cc5b693b3
--- /dev/null
+++ b/pkgs/by-name/aw/awscurl/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3Packages,
+}:
+
+python3Packages.buildPythonApplication (finalAttrs: {
+  pname = "awscurl";
+  version = "0.44";
+  pyproject = true;
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "okigan";
+    repo = "awscurl";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-XMPvAQ7O42HCdVHABe9GENNLIKrYzrpCdfh7dcym2Y8=";
+  };
+
+  build-system = with python3Packages; [
+    setuptools
+  ];
+
+  dependencies = with python3Packages; [
+    awscrt
+    boto3
+    botocore
+    configargparse
+    configparser
+    requests
+    urllib3
+  ];
+
+  nativeCheckInputs = with python3Packages; [
+    pytestCheckHook
+  ];
+
+  disabledTestPaths = [
+    # requires internet
+    "tests/integration_test.py"
+    "tests/tls_test.py"
+  ];
+
+  meta = {
+    description = "Curl like tool with AWS request signing";
+    homepage = "https://github.com/okigan/awscurl";
+    changelog = "https://github.com/okigan/awscurl/releases/tag/${finalAttrs.src.tag}";
+    maintainers = with lib.maintainers; [ SuperSandro2000 ];
+    license = lib.licenses.mit;
+  };
+})