From 21124ba61b0291bbad7c3dac526eaca74ecaf7e3 Mon Sep 17 00:00:00 2001
From: Jared Baur <jaredbaur@fastmail.com>
Date: Wed, 29 Oct 2025 21:18:30 -0700
Subject: [PATCH 1/2] mdio-tools: init at 1.3.1

---
 pkgs/by-name/md/mdio-tools/package.nix | 41 ++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 pkgs/by-name/md/mdio-tools/package.nix

diff --git a/pkgs/by-name/md/mdio-tools/package.nix b/pkgs/by-name/md/mdio-tools/package.nix
new file mode 100644
index 000000000000..4f797a0fdbc0
--- /dev/null
+++ b/pkgs/by-name/md/mdio-tools/package.nix
@@ -0,0 +1,41 @@
+{
+  autoreconfHook,
+  fetchFromGitHub,
+  lib,
+  libmnl,
+  pkg-config,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mdio-tools";
+  version = "1.3.1";
+
+  src = fetchFromGitHub {
+    owner = "wkz";
+    repo = "mdio-tools";
+    tag = finalAttrs.version;
+    hash = "sha256-NomChJrYwMDPXNw5r2p11kGfYUvJBHCdLXy1SA8kOaM=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+  buildInputs = [ libmnl ];
+
+  postPatch = ''
+    substituteInPlace configure.ac \
+      --replace-fail "git describe --always --dirty --tags" "echo ${finalAttrs.version}"
+  '';
+
+  meta = {
+    description = "Low-level debug tools for MDIO devices";
+    homepage = "https://github.com/wkz/mdio-tools";
+    changelog = "https://github.com/wkz/mdio-tools/blob/${finalAttrs.src.rev}/ChangeLog.md";
+    license = lib.licenses.gpl2Only;
+    maintainers = [ lib.maintainers.jmbaur ];
+    mainProgram = "mdio";
+    platforms = lib.platforms.linux;
+  };
+})

From 9bdf1311eeaecd888147452ee1977d9aa327878d Mon Sep 17 00:00:00 2001
From: Jared Baur <jaredbaur@fastmail.com>
Date: Wed, 29 Oct 2025 21:18:44 -0700
Subject: [PATCH 2/2] mdio-netlink: init at 1.3.1

---
 .../linux/mdio-netlink/default.nix            | 29 +++++++++++++++++++
 pkgs/top-level/linux-kernels.nix              |  2 ++
 2 files changed, 31 insertions(+)
 create mode 100644 pkgs/os-specific/linux/mdio-netlink/default.nix

diff --git a/pkgs/os-specific/linux/mdio-netlink/default.nix b/pkgs/os-specific/linux/mdio-netlink/default.nix
new file mode 100644
index 000000000000..3e63364f5b8e
--- /dev/null
+++ b/pkgs/os-specific/linux/mdio-netlink/default.nix
@@ -0,0 +1,29 @@
+{
+  lib,
+  stdenv,
+  kernel,
+  mdio-tools,
+}:
+
+stdenv.mkDerivation {
+  pname = "mdio-netlink";
+  version = "${mdio-tools.version}-${kernel.version}";
+
+  inherit (mdio-tools) src;
+  sourceRoot = "source/kernel";
+
+  nativeBuildInputs = kernel.moduleBuildDependencies;
+
+  makeFlags = kernel.commonMakeFlags ++ [
+    "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
+    "INSTALL_MOD_PATH=${placeholder "out"}"
+  ];
+
+  meta = {
+    description = "Netlink support for MDIO devices";
+    homepage = "https://github.com/wkz/mdio-tools";
+    license = lib.licenses.gpl2Only;
+    maintainers = [ lib.maintainers.jmbaur ];
+    platforms = lib.platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/linux-kernels.nix b/pkgs/top-level/linux-kernels.nix
index 4e00998806b0..3e4f6b6a613c 100644
--- a/pkgs/top-level/linux-kernels.nix
+++ b/pkgs/top-level/linux-kernels.nix
@@ -558,6 +558,8 @@ in
 
         mba6x_bl = callPackage ../os-specific/linux/mba6x_bl { };
 
+        mdio-netlink = callPackage ../os-specific/linux/mdio-netlink { };
+
         mwprocapture = callPackage ../os-specific/linux/mwprocapture { };
 
         mxu11x0 = callPackage ../os-specific/linux/mxu11x0 { };