diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 31a6083a07c3..95eb055073b7 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -4885,6 +4885,12 @@
     githubId = 543423;
     name = "Alex Wied";
   };
+  ceridwen15 = {
+    email = "me@cdwn.gay";
+    github = "NonsensicalNickname";
+    githubId = 118519066;
+    name = "Ceridwen Weaving";
+  };
   cfouche = {
     email = "chaddai.fouche@gmail.com";
     github = "Chaddai";
diff --git a/pkgs/by-name/xr/xroar/package.nix b/pkgs/by-name/xr/xroar/package.nix
new file mode 100644
index 000000000000..80d0cc0f2d40
--- /dev/null
+++ b/pkgs/by-name/xr/xroar/package.nix
@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  testers,
+  wrapGAppsHook3,
+  gobject-introspection,
+  texinfo,
+  pkg-config,
+  autoreconfHook,
+  pulseaudio,
+  libpng,
+  gtk3,
+  gdk-pixbuf,
+  gsettings-desktop-schemas,
+  adwaita-icon-theme,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "xroar";
+  version = "1.13.0.dev-unstable-2026-08-07";
+
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  src = fetchgit {
+    url = "https://www.6809.org.uk/git/xroar.git";
+    rev = "190788e71ae63a4ca44f4e6e66f907852aaf26bb";
+    hash = "sha256-GMOh7EQT7u4JeRnIHaSIZqgTTWK4s/3jXtNscGuOm5w=";
+  };
+
+  nativeBuildInputs = [
+    wrapGAppsHook3
+    gobject-introspection
+
+    texinfo
+    pkg-config
+    autoreconfHook
+  ];
+
+  buildInputs = [
+    pulseaudio
+    libpng
+    gtk3
+    gdk-pixbuf
+    gsettings-desktop-schemas
+    adwaita-icon-theme
+  ];
+
+  passthru.tests.version = testers.testVersion {
+    package = finalAttrs.finalPackage;
+    command = "xroar --version";
+    version = "XRoar ${builtins.elemAt (lib.splitString "-" finalAttrs.version) 0}";
+  };
+
+  meta = {
+    description = "Emulator for the Dragon 32/64; Tandy Colour Computers 1, 2 and 3; the Tandy MC-10; and others";
+    homepage = "https://www.6809.org.uk/xroar/";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [
+      ceridwen15
+    ];
+    platforms = lib.platforms.linux;
+    mainProgram = "xroar";
+  };
+})