From eb5ad54d3f413d069b18ded1de8105c7cb71baab Mon Sep 17 00:00:00 2001
From: eljamm <fedi.jamoussi@protonmail.ch>
Date: Wed, 3 Jun 2026 15:52:56 +0200
Subject: [PATCH] python3Pakcages.licomp-oslc-handbook: init at 0.1.2

Assisted-By: nix-init
---
 .../licomp-oslc-handbook/default.nix          | 67 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 69 insertions(+)
 create mode 100644 pkgs/development/python-modules/licomp-oslc-handbook/default.nix

diff --git a/pkgs/development/python-modules/licomp-oslc-handbook/default.nix b/pkgs/development/python-modules/licomp-oslc-handbook/default.nix
new file mode 100644
index 000000000000..ddc265f9bf1a
--- /dev/null
+++ b/pkgs/development/python-modules/licomp-oslc-handbook/default.nix
@@ -0,0 +1,67 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  setuptools,
+
+  # dependencies
+  licomp,
+
+  # tests
+  pytestCheckHook,
+  jsonschema,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "licomp-oslc-handbook";
+  version = "0.1.2";
+  pyproject = true;
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "hesa";
+    repo = "licomp-oslc-handbook";
+    tag = finalAttrs.version;
+    hash = "sha256-cE3X7oT5Xg1W9lAMLJCYE6qRqrrXpVGLfBp18ynUYLE=";
+    postFetch = ''
+      # conflicts with `licenses` on Darwin, thus producing a different source
+      # hash.
+      mv $out/LICENSES $out/LICENSES_
+    '';
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    licomp
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    jsonschema
+  ];
+
+  pythonImportsCheck = [
+    "licomp_oslc_handbook"
+  ];
+
+  meta = {
+    description = "Licomp implementaiton of OSLC-handbook";
+    homepage = "https://github.com/hesa/licomp-oslc-handbook";
+    changelog = "https://github.com/hesa/licomp-oslc-handbook/releases/tag/${finalAttrs.src.tag}";
+    license = with lib.licenses; [
+      cc-by-40
+      cc-by-sa-40
+      gpl3Plus
+    ];
+    maintainers = with lib.maintainers; [ eljamm ];
+    teams = with lib.teams; [ ngi ];
+    # TODO: remove when this is resolved:
+    # https://github.com/hesa/licomp-oslc-handbook/issues/4
+    badPlatforms = lib.platforms.darwin;
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index c5ec38a8248d..a51e226ce31f 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -9071,6 +9071,8 @@ self: super: with self; {
 
   licomp-osadl = callPackage ../development/python-modules/licomp-osadl { };
 
+  licomp-oslc-handbook = callPackage ../development/python-modules/licomp-oslc-handbook { };
+
   lida = callPackage ../development/python-modules/lida { };
 
   lief = (toPythonModule (pkgs.lief.override { python3 = python; })).py;