{
  lib,
  fetchFromGitHub,
  buildPythonPackage,
  addBinToPathHook,
  pytestCheckHook,
  setuptools,
  setuptools-scm,
  resvg,
  pngquant,
  absl-py,
  fonttools,
  lxml,
  ninja,
  picosvg,
  pillow,
  regex,
  toml,
  tomlkit,
  ufo2ft,
  ufolib2,
  zopfli,
}:

buildPythonPackage rec {
  pname = "nanoemoji";
  version = "0.16.0";
  pyproject = true;

  src = fetchFromGitHub {
    owner = "googlefonts";
    repo = "nanoemoji";
    tag = "v${version}";
    hash = "sha256-FysyKC01XBnRiur5RR9fcsTxQqE8x0JJHSoe3q6JtKc=";
  };

  patches = [
    # this is necessary because the tests clear PATH/PYTHONPATH otherwise
    ./test-pythonpath.patch
  ];

  build-system = [
    setuptools
    setuptools-scm
  ];

  nativeBuildInputs = [
    pngquant
    resvg
  ];

  # these two packages are just prebuilt wheels containing the respective binaries
  pythonRemoveDeps = [
    "pngquant-cli"
    "resvg-cli"
  ];

  dependencies = [
    absl-py
    fonttools
    lxml
    ninja
    picosvg
    pillow
    regex
    toml
    tomlkit
    ufo2ft
    ufolib2
    zopfli
  ];

  nativeCheckInputs = [
    addBinToPathHook
    pytestCheckHook
    ninja
    picosvg
  ];

  makeWrapperArgs = [
    "--prefix"
    "PATH"
    ":"
    (lib.makeBinPath [
      pngquant
      resvg
    ])
  ];

  meta = {
    description = "Wee tool to build color fonts";
    homepage = "https://github.com/googlefonts/nanoemoji";
    changelog = "https://github.com/googlefonts/nanoemoji/releases/tag/${src.tag}";
    license = lib.licenses.asl20;
    maintainers = with lib.maintainers; [ _999eagle ];
  };
}