{
  lib,
  buildPythonPackage,
  fetchFromGitHub,
  pytestCheckHook,
  pythonAtLeast,
  setuptools,
  setuptools-scm,
}:

buildPythonPackage (finalAttrs: {
  pname = "nest-asyncio";
  version = "1.6.0";
  pyproject = true;

  src = fetchFromGitHub {
    owner = "erdewit";
    repo = "nest_asyncio";
    tag = "v${finalAttrs.version}";
    hash = "sha256-5I5WItOl1QpyI4OXZgZf8GiQ7Jlo+SJbDicIbernaU4=";
  };

  postPatch = ''
    substituteInPlace setup.cfg \
      --replace-fail 'version = 1.5.9' 'version = ${finalAttrs.version}'
  '';

  build-system = [
    setuptools
    setuptools-scm
  ];

  nativeCheckInputs = [ pytestCheckHook ];

  disabledTestPaths = lib.optionals (pythonAtLeast "3.14") [
    "tests/nest_test.py::NestTest::test_timeout"
  ];

  pythonImportsCheck = [ "nest_asyncio" ];

  meta = {
    description = "Patch asyncio to allow nested event loops";
    homepage = "https://github.com/erdewit/nest_asyncio";
    changelog = "https://github.com/erdewit/nest_asyncio/releases/tag/${finalAttrs.src.tag}";
    license = lib.licenses.bsdOriginal;
    maintainers = [ ];
  };
})