mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-06-05 21:03:40 +00:00
a338deb8a1
Move the portable modular service base from nixos/modules/system/service/portable/ to lib/services/, making it importable by any module system (home-manager, nix-darwin) without reaching into the nixos/ tree. Moved files: service.nix, lib.nix, config-data.nix, config-data-item.nix, test.nix. All external references updated (systemd/system.nix, doc/manual/default.nix, assertions.nix, README.md). No functional changes - only import paths differ.
55 lines
1.8 KiB
Nix
55 lines
1.8 KiB
Nix
# Non-module arguments
|
|
# These are separate from the module arguments to avoid implicit dependencies.
|
|
# This makes service modules self-contains, allowing mixing of Nixpkgs versions.
|
|
{ pkgs }:
|
|
|
|
# The module
|
|
{
|
|
lib,
|
|
...
|
|
}:
|
|
let
|
|
inherit (lib) mkOption types;
|
|
pathOrStr = types.coercedTo types.path (x: "${x}") types.str;
|
|
in
|
|
{
|
|
# https://nixos.org/manual/nixos/unstable/#modular-services
|
|
_class = "service";
|
|
imports = [
|
|
../../modules/generic/meta-maintainers.nix
|
|
../../nixos/modules/misc/assertions.nix
|
|
(lib.modules.importApply ./config-data.nix { inherit pkgs; })
|
|
];
|
|
options = {
|
|
services = mkOption {
|
|
type = types.attrsOf (
|
|
types.submoduleWith {
|
|
modules = [
|
|
(lib.modules.importApply ./service.nix { inherit pkgs; })
|
|
];
|
|
}
|
|
);
|
|
description = ''
|
|
A collection of [modular services](https://nixos.org/manual/nixos/unstable/#modular-services) that are configured in one go.
|
|
|
|
You could consider the sub-service relationship to be an ownership relation.
|
|
It **does not** automatically create any other relationship between services (e.g. systemd slices), unless perhaps such a behavior is explicitly defined and enabled in another option.
|
|
'';
|
|
default = { };
|
|
visible = "shallow";
|
|
};
|
|
process = {
|
|
argv = lib.mkOption {
|
|
type = types.listOf pathOrStr;
|
|
example = lib.literalExpression ''[ (lib.getExe config.package) "--nobackground" ]'';
|
|
description = ''
|
|
Command filename and arguments for starting this service.
|
|
This is a raw command-line that should not contain any shell escaping.
|
|
If expansion of environmental variables is required then use
|
|
a shell script or `importas` from `pkgs.execline`.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
}
|