mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-08-27 02:34:53 +00:00
654a07279a
Also remove from enableAllTerminfo list.
Since vte: 0.82.3 → 0.84.0 custom patches applied to vte in termite are
broken. The package has been without upstream for 5 years for now.
18de7682e9
https://github.com/NixOS/nixpkgs/issues/122929
104 lines
2.3 KiB
Nix
104 lines
2.3 KiB
Nix
# This module manages the terminfo database
|
|
# and its integration in the system.
|
|
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
{
|
|
|
|
options = {
|
|
environment.enableAllTerminfo = lib.mkOption {
|
|
default = false;
|
|
type = lib.types.bool;
|
|
description = ''
|
|
Whether to install all terminfo outputs
|
|
'';
|
|
};
|
|
|
|
security.sudo.keepTerminfo = lib.mkOption {
|
|
default = true;
|
|
type = lib.types.bool;
|
|
description = ''
|
|
Whether to preserve the `TERMINFO` and `TERMINFO_DIRS`
|
|
environment variables, for `root` and the `wheel` group.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = {
|
|
|
|
# This should not contain packages that are broken or can't build, since it
|
|
# will break this expression
|
|
#
|
|
# can be generated with:
|
|
# lib.attrNames (lib.filterAttrs
|
|
# (_: drv: (builtins.tryEval (lib.isDerivation drv && drv ? terminfo)).value)
|
|
# pkgs)
|
|
environment.systemPackages = lib.mkIf config.environment.enableAllTerminfo (
|
|
map (x: x.terminfo) (
|
|
with pkgs.pkgsBuildBuild;
|
|
[
|
|
alacritty
|
|
contour
|
|
foot
|
|
ghostty
|
|
kitty
|
|
mtm
|
|
rio
|
|
rxvt-unicode-unwrapped
|
|
rxvt-unicode-unwrapped-emoji
|
|
st
|
|
tmux
|
|
wezterm
|
|
yaft
|
|
]
|
|
)
|
|
);
|
|
|
|
environment.pathsToLink = [
|
|
"/share/terminfo"
|
|
];
|
|
|
|
environment.etc.terminfo = {
|
|
source = "${config.system.path}/share/terminfo";
|
|
};
|
|
|
|
boot.initrd.systemd.contents = lib.listToAttrs (
|
|
lib.map
|
|
(ti: lib.nameValuePair "/etc/terminfo/${ti}" { source = "${pkgs.ncurses}/share/terminfo/${ti}"; })
|
|
[
|
|
"l/linux"
|
|
"v/vt100"
|
|
"v/vt102"
|
|
"v/vt220"
|
|
]
|
|
);
|
|
|
|
environment.profileRelativeSessionVariables = {
|
|
TERMINFO_DIRS = [ "/share/terminfo" ];
|
|
};
|
|
|
|
environment.extraInit = ''
|
|
|
|
# reset TERM with new TERMINFO available (if any)
|
|
export TERM=$TERM
|
|
'';
|
|
|
|
security =
|
|
let
|
|
extraConfig = ''
|
|
|
|
# Keep terminfo database for root and %wheel.
|
|
Defaults:root,%wheel env_keep+=TERMINFO_DIRS
|
|
Defaults:root,%wheel env_keep+=TERMINFO
|
|
'';
|
|
in
|
|
lib.mkIf config.security.sudo.keepTerminfo {
|
|
sudo = { inherit extraConfig; };
|
|
sudo-rs = { inherit extraConfig; };
|
|
};
|
|
};
|
|
}
|