mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-02 13:00:23 +00:00
667d42c00d
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build a08b3a4d19.tar.gz \
--argstr baseRev 57b193d8dd
result/bin/apply-formatting $NIXPKGS_PATH
48 lines
1.7 KiB
Nix
48 lines
1.7 KiB
Nix
# Deprecated aliases - for backward compatibility
|
|
|
|
lib: overridden:
|
|
|
|
let
|
|
# Removing recurseForDerivation prevents derivations of aliased attribute
|
|
# set to appear while listing all the packages available.
|
|
removeRecurseForDerivations =
|
|
alias:
|
|
if alias.recurseForDerivations or false then
|
|
lib.removeAttrs alias [ "recurseForDerivations" ]
|
|
else
|
|
alias;
|
|
|
|
# Disabling distribution prevents top-level aliases for non-recursed package
|
|
# sets from building on Hydra.
|
|
removeDistribute = alias: if lib.isDerivation alias then lib.dontDistribute alias else alias;
|
|
|
|
# Make sure that we are not shadowing something from
|
|
# all-packages.nix.
|
|
checkInPkgs =
|
|
n: alias:
|
|
if builtins.hasAttr n overridden then throw "Alias ${n} is still in kakounePlugins" else alias;
|
|
|
|
mapAliases =
|
|
aliases:
|
|
lib.mapAttrs (
|
|
n: alias: removeDistribute (removeRecurseForDerivations (checkInPkgs n alias))
|
|
) aliases;
|
|
|
|
deprecations = lib.mapAttrs (
|
|
old: info: throw "${old} was renamed to ${info.new} on ${info.date}. Please update to ${info.new}."
|
|
) (lib.importJSON ./deprecated.json);
|
|
|
|
in
|
|
mapAliases (
|
|
{
|
|
kak-auto-pairs = overridden.auto-pairs-kak; # backwards compat, added 2021-01-04
|
|
kak-buffers = overridden.kakoune-buffers; # backwards compat, added 2021-01-04
|
|
kak-byline = overridden.byline-kak; # backwards compat, added 2023-10-22
|
|
kak-fzf = overridden.fzf-kak; # backwards compat, added 2021-01-04
|
|
kak-powerline = overridden.powerline-kak; # backwards compat, added 2021-01-04
|
|
kak-prelude = overridden.prelude-kak; # backwards compat, added 2021-01-04
|
|
kak-vertical-selection = overridden.kakoune-vertical-selection; # backwards compat, added 2021-01-04
|
|
}
|
|
// deprecations
|
|
)
|