mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-03 21:40:12 +00:00
328 lines
11 KiB
Nix
328 lines
11 KiB
Nix
{
|
||
lib,
|
||
stdenv,
|
||
fetchurl,
|
||
pkg-config,
|
||
perl,
|
||
nixosTests,
|
||
autoreconfHook,
|
||
buildPackages,
|
||
runtimeShellPackage,
|
||
brotliSupport ? false,
|
||
brotli,
|
||
c-aresSupport ? false,
|
||
c-aresMinimal,
|
||
gnutlsSupport ? false,
|
||
gnutls,
|
||
gsaslSupport ? false,
|
||
gsasl,
|
||
gssSupport ?
|
||
with stdenv.hostPlatform;
|
||
(
|
||
# krb5 is broken on cygwin
|
||
!(isWindows || isCygwin)
|
||
&&
|
||
# disable gss because of: undefined reference to `k5_bcmp'
|
||
# a very sad story re static: https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=439039
|
||
!isStatic
|
||
&&
|
||
# the "mig" tool does not configure its compiler correctly. This could be
|
||
# fixed in mig, but losing gss support on cross compilation to darwin is
|
||
# not worth the effort.
|
||
!(isDarwin && (stdenv.buildPlatform != stdenv.hostPlatform))
|
||
),
|
||
libkrb5,
|
||
http2Support ? true,
|
||
nghttp2,
|
||
http3Support ? false,
|
||
nghttp3,
|
||
ngtcp2,
|
||
websocketSupport ? false,
|
||
idnSupport ? false,
|
||
libidn2,
|
||
ldapSupport ? false,
|
||
openldap,
|
||
opensslSupport ? zlibSupport,
|
||
openssl,
|
||
pslSupport ? false,
|
||
libpsl,
|
||
scpSupport ? zlibSupport && !stdenv.hostPlatform.isSunOS && !stdenv.hostPlatform.isCygwin,
|
||
libssh2,
|
||
rustlsSupport ? false,
|
||
rustls-ffi,
|
||
zlibSupport ? true,
|
||
zlib,
|
||
zstdSupport ? false,
|
||
zstd,
|
||
|
||
# for passthru.tests
|
||
coeurl,
|
||
curlpp,
|
||
haskellPackages,
|
||
ocamlPackages,
|
||
phpExtensions,
|
||
pkgsStatic,
|
||
python3,
|
||
tests,
|
||
testers,
|
||
fetchpatch,
|
||
}:
|
||
|
||
# Note: this package is used for bootstrapping fetchurl, and thus
|
||
# cannot use fetchpatch! All mutable patches (generated by GitHub or
|
||
# cgit) that are needed here should be included directly in Nixpkgs as
|
||
# files.
|
||
|
||
assert
|
||
!(
|
||
(lib.count (x: x) [
|
||
gnutlsSupport
|
||
opensslSupport
|
||
rustlsSupport
|
||
]) > 1
|
||
);
|
||
|
||
let
|
||
isCross = !lib.systems.equals stdenv.buildPlatform stdenv.hostPlatform;
|
||
in
|
||
stdenv.mkDerivation (finalAttrs: {
|
||
pname = "curl";
|
||
version = "8.22.0";
|
||
|
||
src = fetchurl {
|
||
urls = [
|
||
"https://curl.haxx.se/download/curl-${finalAttrs.version}.tar.xz"
|
||
"https://github.com/curl/curl/releases/download/curl-${
|
||
builtins.replaceStrings [ "." ] [ "_" ] finalAttrs.version
|
||
}/curl-${finalAttrs.version}.tar.xz"
|
||
];
|
||
hash = "sha256-9+866KIuUh8omAP+k1Q+tkwym1iqc6niJN/ZFaKl9Pc=";
|
||
};
|
||
|
||
# this could be accomplished by updateAutotoolsGnuConfigScriptsHook, but that causes infinite recursion
|
||
# necessary for FreeBSD code path in configure
|
||
postPatch = ''
|
||
substituteInPlace ./config.guess --replace-fail /usr/bin/uname uname
|
||
''
|
||
# `wcurl` is the one thing in `scripts` that is installed, so it is the one
|
||
# whose shebang has to suit the host platform. The rest are only used during
|
||
# the build, and want this platform's shell. Say which is which rather than
|
||
# patch them all one way and correct it afterwards.
|
||
#
|
||
# Where the host has no shell at all, `patchShebangs --host` finds nothing
|
||
# and leaves the shebang as shipped, which is the best available answer.
|
||
+ ''
|
||
local f flag
|
||
for f in scripts/*; do
|
||
if [[ "$f" == scripts/wcurl ]]; then
|
||
flag=--host
|
||
else
|
||
flag=--build
|
||
fi
|
||
patchShebangs "$flag" "$f"
|
||
done
|
||
'';
|
||
|
||
outputs = [
|
||
"bin"
|
||
"dev"
|
||
"out"
|
||
"man"
|
||
"devdoc"
|
||
];
|
||
separateDebugInfo = stdenv.hostPlatform.isLinux;
|
||
|
||
enableParallelBuilding = true;
|
||
|
||
strictDeps = true;
|
||
__structuredAttrs = true;
|
||
|
||
env = {
|
||
CXX = "${stdenv.cc.targetPrefix}c++";
|
||
CXXCPP = "${stdenv.cc.targetPrefix}c++ -E";
|
||
}
|
||
// lib.optionalAttrs (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isStatic) {
|
||
# Not having this causes curl’s `configure` script to fail with static builds on Darwin because
|
||
# some of curl’s propagated inputs need libiconv.
|
||
NIX_LDFLAGS = "-liconv";
|
||
};
|
||
|
||
nativeBuildInputs = [
|
||
pkg-config
|
||
perl
|
||
]
|
||
++ lib.optionals stdenv.hostPlatform.isOpenBSD [ autoreconfHook ];
|
||
|
||
nativeCheckInputs = [
|
||
# See https://github.com/curl/curl/pull/16928
|
||
openssl
|
||
];
|
||
|
||
# Zlib and OpenSSL must be propagated because `libcurl.la' contains
|
||
# "-lz -lssl", which aren't necessary direct build inputs of
|
||
# applications that use Curl.
|
||
propagatedBuildInputs =
|
||
lib.optional brotliSupport brotli
|
||
++ lib.optional c-aresSupport c-aresMinimal
|
||
++ lib.optional gnutlsSupport gnutls
|
||
++ lib.optional gsaslSupport gsasl
|
||
++ lib.optional gssSupport libkrb5
|
||
++ lib.optional http2Support nghttp2
|
||
++ lib.optionals http3Support [
|
||
nghttp3
|
||
ngtcp2
|
||
]
|
||
++ lib.optional idnSupport libidn2
|
||
++ lib.optional ldapSupport openldap
|
||
++ lib.optional opensslSupport openssl
|
||
++ lib.optional pslSupport libpsl
|
||
++ lib.optional scpSupport libssh2
|
||
++ lib.optional rustlsSupport rustls-ffi
|
||
++ lib.optional zlibSupport zlib
|
||
++ lib.optional zstdSupport zstd;
|
||
|
||
# for the second line see https://curl.haxx.se/mail/tracker-2014-03/0087.html
|
||
preConfigure = ''
|
||
sed -e 's|/usr/bin|/no-such-path|g' -i.bak configure
|
||
rm src/tool_hugehelp.c
|
||
'';
|
||
|
||
configureFlags = [
|
||
"--enable-versioned-symbols"
|
||
# Build without manual
|
||
"--disable-manual"
|
||
(lib.enableFeature c-aresSupport "ares")
|
||
(lib.enableFeature ldapSupport "ldap")
|
||
(lib.enableFeature ldapSupport "ldaps")
|
||
(lib.enableFeature websocketSupport "websockets")
|
||
# --with-ca-fallback is only supported for openssl https://github.com/curl/curl/blame/curl-8_16_0/acinclude.m4#L1258
|
||
(lib.withFeature opensslSupport "ca-fallback")
|
||
(lib.withFeature http3Support "nghttp3")
|
||
(lib.withFeature http3Support "ngtcp2")
|
||
(lib.withFeature rustlsSupport "rustls")
|
||
(lib.withFeature zstdSupport "zstd")
|
||
(lib.withFeature pslSupport "libpsl")
|
||
(lib.withFeatureAs brotliSupport "brotli" (lib.getDev brotli))
|
||
(lib.withFeatureAs gnutlsSupport "gnutls" (lib.getDev gnutls))
|
||
(lib.withFeatureAs idnSupport "libidn2" (lib.getDev libidn2))
|
||
(lib.withFeatureAs opensslSupport "openssl" (lib.getDev openssl))
|
||
(lib.withFeatureAs scpSupport "libssh2" (lib.getDev libssh2))
|
||
]
|
||
++ lib.optional gssSupport "--with-gssapi=${lib.getDev libkrb5}"
|
||
# For the 'urandom', maybe it should be a cross-system option
|
||
++ lib.optional (stdenv.hostPlatform != stdenv.buildPlatform) "--with-random=/dev/urandom"
|
||
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
||
# Disable default CA bundle, use NIX_SSL_CERT_FILE or fallback to nss-cacert from the default profile.
|
||
# Without this curl might detect /etc/ssl/cert.pem at build time on macOS, causing curl to ignore NIX_SSL_CERT_FILE.
|
||
"--without-ca-bundle"
|
||
"--without-ca-path"
|
||
]
|
||
++ lib.optionals (!gnutlsSupport && !opensslSupport && !rustlsSupport) [
|
||
"--without-ssl"
|
||
]
|
||
++ lib.optionals (rustlsSupport && !stdenv.hostPlatform.isDarwin) [
|
||
"--with-ca-bundle=/etc/ssl/certs/ca-certificates.crt"
|
||
]
|
||
++ lib.optionals (gnutlsSupport && !stdenv.hostPlatform.isDarwin) [
|
||
"--with-ca-path=/etc/ssl/certs"
|
||
];
|
||
|
||
# takes 14 minutes on a 24 core and because many other packages depend on curl
|
||
# they cannot be run concurrently and are a bottleneck
|
||
# tests are available in passthru.tests.withCheck
|
||
doCheck = false;
|
||
preCheck = ''
|
||
patchShebangs tests/
|
||
''
|
||
+ lib.optionalString stdenv.hostPlatform.isDarwin ''
|
||
# bad interaction with sandbox if enabled?
|
||
rm tests/data/test1453
|
||
rm tests/data/test1086
|
||
''
|
||
+ lib.optionalString stdenv.hostPlatform.isMusl ''
|
||
# different resolving behaviour?
|
||
rm tests/data/test1592
|
||
'';
|
||
|
||
__darwinAllowLocalNetworking = true;
|
||
|
||
postInstall = ''
|
||
moveToOutput bin/curl-config "$dev"
|
||
|
||
# Install completions
|
||
make -C scripts install
|
||
''
|
||
+ lib.optionalString scpSupport ''
|
||
sed '/^dependency_libs/s|${lib.getDev libssh2}|${lib.getLib libssh2}|' -i "$out"/lib/*.la
|
||
''
|
||
+ lib.optionalString gnutlsSupport ''
|
||
ln $out/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} $out/lib/libcurl-gnutls${stdenv.hostPlatform.extensions.sharedLibrary}
|
||
ln $out/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} $out/lib/libcurl-gnutls${stdenv.hostPlatform.extensions.sharedLibrary}.4
|
||
ln $out/lib/libcurl${stdenv.hostPlatform.extensions.sharedLibrary} $out/lib/libcurl-gnutls${stdenv.hostPlatform.extensions.sharedLibrary}.4.4.0
|
||
''
|
||
# `postPatch` above should have pointed everything installed at the host's
|
||
# shell already. Do it again over what was installed, defensively.
|
||
+ lib.optionalString isCross ''
|
||
patchShebangs --host "''${!outputBin}/bin"
|
||
'';
|
||
|
||
# Whether we patch the shebangs in the installed script or not, we should not
|
||
# have build platform software in the final runtime closure.
|
||
outputChecks.bin.disallowedReferences = lib.optional isCross buildPackages.runtimeShellPackage;
|
||
outputChecks.out.disallowedReferences = lib.optional isCross buildPackages.runtimeShellPackage;
|
||
|
||
# Some hosts have no shell for the scripts to point at: MinGW is the one in
|
||
# tree, where `bash` is marked unsupported because it needs a POSIX layer. We
|
||
# cannot patch shebangs in that case.
|
||
buildInputs = lib.optional (lib.meta.availableOn stdenv.hostPlatform runtimeShellPackage) runtimeShellPackage;
|
||
|
||
passthru =
|
||
let
|
||
useThisCurl = attr: attr.override { curl = finalAttrs.finalPackage; };
|
||
in
|
||
{
|
||
inherit opensslSupport openssl;
|
||
tests = {
|
||
withCheck = finalAttrs.finalPackage.overrideAttrs (_: {
|
||
doCheck = true;
|
||
});
|
||
fetchpatch = tests.fetchpatch.simple.override {
|
||
fetchpatch = (fetchpatch.override { fetchurl = useThisCurl fetchurl; }) // {
|
||
version = 1;
|
||
};
|
||
};
|
||
curlpp = useThisCurl curlpp;
|
||
coeurl = useThisCurl coeurl;
|
||
haskell-curl = useThisCurl haskellPackages.curl;
|
||
ocaml-curly = useThisCurl ocamlPackages.curly;
|
||
pycurl = useThisCurl python3.pkgs.pycurl;
|
||
php-curl = useThisCurl phpExtensions.curl;
|
||
# error: attribute 'override' missing
|
||
# Additional checking with support http3 protocol.
|
||
# nginx-http3 = useThisCurl nixosTests.nginx-http3;
|
||
nginx-http3 = nixosTests.nginx-http3;
|
||
pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
|
||
static = pkgsStatic.curl;
|
||
};
|
||
};
|
||
|
||
meta = {
|
||
changelog = "https://curl.se/ch/${finalAttrs.version}.html";
|
||
description = "Command line tool for transferring files with URL syntax";
|
||
homepage = "https://curl.se/";
|
||
donationPage = "https://curl.se/donation.html";
|
||
license = lib.licenses.curl;
|
||
maintainers = with lib.maintainers; [
|
||
Scrumplex
|
||
tmarkus
|
||
];
|
||
teams = [ lib.teams.security-review ];
|
||
platforms = lib.platforms.all;
|
||
# Fails to link against static gss
|
||
broken = stdenv.hostPlatform.isStatic && gssSupport;
|
||
pkgConfigModules = [ "libcurl" ];
|
||
mainProgram = "curl";
|
||
identifiers.cpeParts = lib.meta.cpeFullVersionWithVendor "haxx" finalAttrs.version;
|
||
};
|
||
})
|