mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-03 21:40:12 +00:00
567e8dfd8e
This commit was created by a combination of scripts and tools: - an ast-grep script to prefix things in meta with `lib.`, - a modified nixf-diagnose / nixf combination to remove unused `with lib;`, and - regular nixfmt. Co-authored-by: Wolfgang Walther <walther@technowledgy.de>
52 lines
1.3 KiB
Nix
52 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
fetchFromGitHub,
|
|
jdk11,
|
|
maven,
|
|
jogl,
|
|
}:
|
|
|
|
maven.buildMavenPackage rec {
|
|
pname = "gephi";
|
|
version = "0.10.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gephi";
|
|
repo = "gephi";
|
|
rev = "v${version}";
|
|
hash = "sha256-ZNSEaiD32zFfF2ISKa1CmcT9Nq6r5i2rNHooQAcVbn4=";
|
|
};
|
|
|
|
mvnJdk = jdk11;
|
|
mvnHash = "sha256-/2/Yb26Ry0NHQQ3j0LXnjwC0wQqJiztvTgWixyMJqvg=";
|
|
|
|
nativeBuildInputs = [ jdk11 ];
|
|
|
|
installPhase = ''
|
|
cp -r modules/application/target/gephi $out
|
|
|
|
# remove garbage
|
|
find $out -type f -name .lastModified -delete
|
|
find $out -type f -regex '.+\.exe' -delete
|
|
|
|
# use self-compiled JOGL to avoid patchelf'ing .so inside jars
|
|
rm $out/gephi/modules/ext/org.gephi.visualization/org-jogamp-{jogl,gluegen}/*.jar
|
|
cp ${jogl}/share/java/jogl*.jar $out/gephi/modules/ext/org.gephi.visualization/org-jogamp-jogl/
|
|
cp ${jogl}/share/java/glue*.jar $out/gephi/modules/ext/org.gephi.visualization/org-jogamp-gluegen/
|
|
|
|
printf "\n\njdkhome=${jdk11}\n" >> $out/etc/gephi.conf
|
|
'';
|
|
|
|
meta = {
|
|
description = "Platform for visualizing and manipulating large graphs";
|
|
mainProgram = "gephi";
|
|
homepage = "https://gephi.org";
|
|
sourceProvenance = with lib.sourceTypes; [
|
|
fromSource
|
|
binaryBytecode # deps
|
|
];
|
|
license = lib.licenses.gpl3;
|
|
maintainers = [ lib.maintainers.taeer ];
|
|
};
|
|
}
|