mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-03 13:30:36 +00:00
567e8dfd8e
This commit was created by a combination of scripts and tools: - an ast-grep script to prefix things in meta with `lib.`, - a modified nixf-diagnose / nixf combination to remove unused `with lib;`, and - regular nixfmt. Co-authored-by: Wolfgang Walther <walther@technowledgy.de>
63 lines
1.2 KiB
Nix
63 lines
1.2 KiB
Nix
{
|
|
stdenvNoCC,
|
|
lib,
|
|
fetchFromGitHub,
|
|
hyprland,
|
|
jq,
|
|
grim,
|
|
slurp,
|
|
wl-clipboard,
|
|
libnotify,
|
|
withFreeze ? true,
|
|
hyprpicker,
|
|
makeWrapper,
|
|
}:
|
|
|
|
stdenvNoCC.mkDerivation (finalAttrs: {
|
|
pname = "hyprshot";
|
|
version = "1.3.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Gustash";
|
|
repo = "hyprshot";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-9taTmV357cWglMGuN3NLq3bfNneFthwV6y+Ml4qEeHA=";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
install -Dm755 hyprshot -t "$out/bin"
|
|
wrapProgram "$out/bin/hyprshot" \
|
|
--prefix PATH ":" ${
|
|
lib.makeBinPath (
|
|
[
|
|
hyprland
|
|
jq
|
|
grim
|
|
slurp
|
|
wl-clipboard
|
|
libnotify
|
|
]
|
|
++ lib.optionals withFreeze [ hyprpicker ]
|
|
)
|
|
}
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "https://github.com/Gustash/hyprshot";
|
|
description = "Utility to easily take screenshots in Hyprland using your mouse";
|
|
license = lib.licenses.gpl3Only;
|
|
maintainers = with lib.maintainers; [
|
|
Cryolitia
|
|
ryan4yin
|
|
];
|
|
mainProgram = "hyprshot";
|
|
platforms = hyprland.meta.platforms;
|
|
};
|
|
})
|