mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-04 14:00:04 +00:00
a3b1c0f185
Update `pulumi`, as well as all derivations which reuse its `src` and `version` (pulumi-go, pulumi-nodejs, pulumi-python vendorHash bumps). Skip nine new `pulumi new` tests that require `pulumi-language-yaml`. Changelog: https://github.com/pulumi/pulumi/blob/v3.261.0/CHANGELOG.md Assisted-by: Claude Code (Claude Fable 5.1) Co-Authored-By: Claude Fable 5.1 <noreply@anthropic.com>
60 lines
1.3 KiB
Nix
60 lines
1.3 KiB
Nix
{
|
|
lib,
|
|
buildGoModule,
|
|
callPackage,
|
|
pulumi,
|
|
bash,
|
|
python3,
|
|
}:
|
|
buildGoModule (finalAttrs: {
|
|
pname = "pulumi-python";
|
|
inherit (pulumi) version src;
|
|
|
|
sourceRoot = "${finalAttrs.src.name}/sdk/python/cmd/pulumi-language-python";
|
|
|
|
vendorHash = "sha256-nm9749kcfio/q2Y5XxqdiQ8IwLP/2jjZOEBF9SCyJAA=";
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X=github.com/pulumi/pulumi/sdk/v3/go/common/version.Version=${finalAttrs.version}"
|
|
];
|
|
|
|
checkFlags = [
|
|
"-skip=^${
|
|
lib.concatStringsSep "$|^" [
|
|
"TestLanguageDefault"
|
|
"TestLanguageTOML"
|
|
"TestLanguageClasses"
|
|
"TestListPulumiPackageInfos"
|
|
]
|
|
}$"
|
|
];
|
|
|
|
nativeCheckInputs = [
|
|
python3
|
|
];
|
|
|
|
# For patchShebangsAuto (see scripts copied in postInstall).
|
|
buildInputs = [
|
|
bash
|
|
python3
|
|
];
|
|
|
|
postInstall = ''
|
|
cp -t "$out/bin" \
|
|
../pulumi-language-python-exec \
|
|
../../dist/pulumi-resource-pulumi-python
|
|
'';
|
|
|
|
passthru.tests.smokeTest = callPackage ./smoke-test/default.nix { };
|
|
|
|
meta = {
|
|
homepage = "https://www.pulumi.com/docs/iac/languages-sdks/python/";
|
|
description = "Language host for Pulumi programs written in Python";
|
|
license = lib.licenses.asl20;
|
|
mainProgram = "pulumi-language-python";
|
|
maintainers = lib.teams.pulumi.members;
|
|
};
|
|
})
|