mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-04 05:50:00 +00:00
d2cc156b6f
Diff: https://github.com/roadrunner-server/roadrunner/compare/v2025.1.14...v2025.1.15 Changelog: https://github.com/roadrunner-server/roadrunner/blob/v2025.1.15/CHANGELOG.md
59 lines
1.8 KiB
Nix
59 lines
1.8 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
installShellFiles,
|
|
versionCheckHook,
|
|
}:
|
|
|
|
buildGoModule (finalAttrs: {
|
|
pname = "roadrunner";
|
|
version = "2025.1.15";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "roadrunner-server";
|
|
repo = "roadrunner";
|
|
tag = "v${finalAttrs.version}";
|
|
hash = "sha256-T7JWA/O25s7A/jSrWJJF4oJbQD0hQyCRt6vFiuz8kwE=";
|
|
};
|
|
|
|
vendorHash = "sha256-OhfqfLYHCoBU8QyrpaHwKXtGZf5eK8ocfTyjtZxsgSg=";
|
|
env.GOWORK = "off";
|
|
|
|
subPackages = [ "cmd/rr" ];
|
|
|
|
# Flags as provided by the build automation of the project:
|
|
# https://github.com/roadrunner-server/roadrunner/blob/3853ad693522e82d53d62950e5f1315402c910f2/.github/workflows/release.yml#L82
|
|
ldflags = [
|
|
"-s"
|
|
"-X=github.com/roadrunner-server/roadrunner/v${lib.versions.major finalAttrs.version}/internal/meta.version=${finalAttrs.version}"
|
|
"-X=github.com/roadrunner-server/roadrunner/v${lib.versions.major finalAttrs.version}/internal/meta.buildTime=1970-01-01T00:00:00Z"
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
];
|
|
|
|
postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
installShellCompletion --cmd rr \
|
|
--bash <($out/bin/rr completion bash) \
|
|
--zsh <($out/bin/rr completion zsh) \
|
|
--fish <($out/bin/rr completion fish)
|
|
'';
|
|
|
|
__darwinAllowLocalNetworking = true;
|
|
|
|
doInstallCheck = true;
|
|
nativeInstallCheckInputs = [ versionCheckHook ];
|
|
|
|
meta = {
|
|
changelog = "https://github.com/roadrunner-server/roadrunner/blob/v${finalAttrs.version}/CHANGELOG.md";
|
|
description = "High-performance PHP application server, process manager written in Go and powered with plugins";
|
|
homepage = "https://roadrunner.dev";
|
|
license = lib.licenses.mit;
|
|
mainProgram = "rr";
|
|
maintainers = with lib.maintainers; [ moraxyc ];
|
|
};
|
|
})
|