mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-08-27 02:34:53 +00:00
e5699f2308
`plv8` depends on the outdated NodeJS 20. Upstream waits for v8-cmake to make a move (https://github.com/plv8/plv8/issues/610), but that project has been inactive for a bit more than a year. Even when allowing the insecure nodejs20, the package fails to build. Insecure and broken - we might as well drop it.
29 lines
1.8 KiB
Nix
29 lines
1.8 KiB
Nix
self: super:
|
|
let
|
|
inherit (self) lib config;
|
|
in
|
|
(lib.packagesFromDirectoryRecursive {
|
|
inherit (super) callPackage;
|
|
directory = ./ext;
|
|
})
|
|
// {
|
|
inherit (super) callPackage;
|
|
|
|
timescaledb-apache = super.callPackage ./ext/timescaledb.nix { enableUnfree = false; };
|
|
}
|
|
// lib.optionalAttrs (!self.perlSupport) {
|
|
plperl = throw "PostgreSQL extension `plperl` is not available, because `postgresql` was built without Perl support. Override with `perlSupport = true` to enable the extension.";
|
|
}
|
|
// lib.optionalAttrs (!self.pythonSupport) {
|
|
plpython3 = throw "PostgreSQL extension `plpython3` is not available, because `postgresql` was built without Python support. Override with `pythonSupport = true` to enable the extension.";
|
|
}
|
|
// lib.optionalAttrs (!self.tclSupport) {
|
|
pltcl = throw "PostgreSQL extension `pltcl` is not available, because `postgresql` was built without Tcl support. Override with `tclSupport = true` to enable the extension.";
|
|
}
|
|
// lib.optionalAttrs config.allowAliases {
|
|
cstore_fdw = throw "PostgreSQL extension `cstore_fdw` has been removed due to being broken for more than a year; see RFC 180"; # Added 2026-02-05
|
|
pg_embedding = throw "PostgreSQL extension `pg_embedding` has been removed since the project has been abandoned. Upstream's recommendation is to use pgvector instead (https://neon.tech/docs/extensions/pg_embedding#migrate-from-pg_embedding-to-pgvector)";
|
|
pgvecto-rs = throw "PostgreSQL extension `pgvecto-rs` has been removed since the project has been abandoned. Upstream's recommendation is to use vectorchord instead (https://docs.vectorchord.ai/vectorchord/admin/migration.html#from-pgvecto-rs) "; # Added 2026-03-13
|
|
plv8 = throw "PostgreSQL extension `plv8` has been removed due to depending on the insecure NodeJS 20"; # Added 2026-06-13
|
|
}
|