mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-30 16:10:36 +00:00
bdb86c177f
Fails as follows: https://nixpkgs-update-logs.nixos.org/python3Packages.mlx-bin/2026-10-06.log error: mlx-bin: unsupported Python version or system: 3.14-x86_64-linux Even if we were to fix the update script to work under linux, the bot won't post an update anyway because it only posts for changes that produce at least one linux derivation change.
55 lines
1.3 KiB
Nix
55 lines
1.3 KiB
Nix
{
|
|
buildPythonPackage,
|
|
callPackage,
|
|
fetchPypi,
|
|
lib,
|
|
macosVariant ? "14",
|
|
}:
|
|
|
|
let
|
|
wheelSources = import ./wheel-sources.nix;
|
|
srcs = lib.mapAttrs (
|
|
_: source:
|
|
fetchPypi {
|
|
pname = "mlx_metal";
|
|
inherit (wheelSources) version;
|
|
format = "wheel";
|
|
dist = "py3";
|
|
python = "py3";
|
|
abi = "none";
|
|
inherit (source) platform hash;
|
|
}
|
|
) wheelSources.mlx-metal;
|
|
in
|
|
buildPythonPackage rec {
|
|
pname = "mlx-metal";
|
|
inherit (wheelSources) version;
|
|
format = "wheel";
|
|
__structuredAttrs = true;
|
|
|
|
src = srcs.${macosVariant} or (throw "mlx-metal: unsupported macOS wheel variant ${macosVariant}");
|
|
|
|
passthru = {
|
|
inherit macosVariant srcs;
|
|
# The bot requires a Linux build, but these wheels only support Darwin.
|
|
# nixpkgs-update: no auto update
|
|
updateScript = callPackage ./update-wheels.nix { };
|
|
};
|
|
|
|
meta = {
|
|
description = "Prebuilt Metal runtime for MLX";
|
|
homepage = "https://github.com/ml-explore/mlx";
|
|
changelog = "https://github.com/ml-explore/mlx/releases/tag/v${version}";
|
|
license = with lib.licenses; [
|
|
mit
|
|
asl20 # Bundled metal-cpp headers
|
|
];
|
|
maintainers = with lib.maintainers; [
|
|
booxter
|
|
kinnrai
|
|
];
|
|
sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
|
|
platforms = [ "aarch64-darwin" ];
|
|
};
|
|
}
|