nathan/nixpkgs
1
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2026-08-25 17:55:21 +00:00
Code Issues Packages Projects Releases Wiki Activity

sqlite: add 3.30 variant for firefox

Browse Source
This commit is contained in:
Andreas Rammhold
2019-11-01 21:53:07 +01:00
parent bcdedc8aff
commit 098dbcd76a
2 changed files with 86 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

84
pkgs/development/libraries/sqlite/3-30.nix Normal file
View File

@@ -0,0 +1,84 @@
{ stdenv, fetchurl, zlib, interactive ? false, readline ? null, ncurses ? null }:
assert interactive -> readline != null && ncurses != null;
with stdenv.lib;
let
archiveVersion = import ./archive-version.nix stdenv.lib;
in
stdenv.mkDerivation rec {
pname = "sqlite";
version = "3.30.0";
# NB! Make sure to update analyzer.nix src (in the same directory).
src = fetchurl {
url = "https://sqlite.org/2019/sqlite-autoconf-${archiveVersion version}.tar.gz";
sha256 = "1hxpi45crbqp6lacl7z611lna02k956m9bsy2bjzrbb2y23546yn";
};
outputs = [ "bin" "dev" "out" ];
separateDebugInfo = stdenv.isLinux;
buildInputs = [ zlib ] ++ optionals interactive [ readline ncurses ];
configureFlags = [ "--enable-threadsafe" ] ++ optional interactive "--enable-readline";
NIX_CFLAGS_COMPILE = [
"-DSQLITE_ENABLE_COLUMN_METADATA"
"-DSQLITE_ENABLE_DBSTAT_VTAB"
"-DSQLITE_ENABLE_JSON1"
"-DSQLITE_ENABLE_FTS3"
"-DSQLITE_ENABLE_FTS3_PARENTHESIS"
"-DSQLITE_ENABLE_FTS3_TOKENIZER"
"-DSQLITE_ENABLE_FTS4"
"-DSQLITE_ENABLE_FTS5"
"-DSQLITE_ENABLE_RTREE"
"-DSQLITE_ENABLE_STMT_SCANSTATUS"
"-DSQLITE_ENABLE_UNLOCK_NOTIFY"
"-DSQLITE_SOUNDEX"
"-DSQLITE_SECURE_DELETE"
"-DSQLITE_MAX_VARIABLE_NUMBER=250000"
"-DSQLITE_MAX_EXPR_DEPTH=10000"
];
# Test for features which may not be available at compile time
preBuild = ''
# Use pread(), pread64(), pwrite(), pwrite64() functions for better performance if they are available.
if cc -Werror=implicit-function-declaration -x c - -o "$TMPDIR/pread_pwrite_test" <<< \
''$'#include <unistd.h>\nint main()\n{\n pread(0, NULL, 0, 0);\n pwrite(0, NULL, 0, 0);\n return 0;\n}'; then
export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -DUSE_PREAD"
fi
if cc -Werror=implicit-function-declaration -x c - -o "$TMPDIR/pread64_pwrite64_test" <<< \
''$'#include <unistd.h>\nint main()\n{\n pread64(0, NULL, 0, 0);\n pwrite64(0, NULL, 0, 0);\n return 0;\n}'; then
export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -DUSE_PREAD64"
elif cc -D_LARGEFILE64_SOURCE -Werror=implicit-function-declaration -x c - -o "$TMPDIR/pread64_pwrite64_test" <<< \
''$'#include <unistd.h>\nint main()\n{\n pread64(0, NULL, 0, 0);\n pwrite64(0, NULL, 0, 0);\n return 0;\n}'; then
export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -DUSE_PREAD64 -D_LARGEFILE64_SOURCE"
fi
# Necessary for FTS5 on Linux
export NIX_LDFLAGS="$NIX_LDFLAGS -lm"
echo ""
echo "NIX_CFLAGS_COMPILE = $NIX_CFLAGS_COMPILE"
echo ""
'';
postInstall = ''
# Do not contaminate dependent libtool-based projects with sqlite dependencies.
sed -i $out/lib/libsqlite3.la -e "s/dependency_libs=.*/dependency_libs='''/"
'';
doCheck = false; # fails to link against tcl
meta = {
description = "A self-contained, serverless, zero-configuration, transactional SQL database engine";
downloadPage = https://sqlite.org/download.html;
homepage = https://www.sqlite.org/;
license = licenses.publicDomain;
maintainers = with maintainers; [ eelco np ];
platforms = platforms.unix ++ platforms.windows;
};
}

2
pkgs/top-level/all-packages.nix
View File

@@ -13644,6 +13644,7 @@ in
stxxl = callPackage ../development/libraries/stxxl { parallel = true; };
sqlite = lowPrio (callPackage ../development/libraries/sqlite { });
sqlite_3_30 = callPackage ../development/libraries/sqlite/3-30.nix { };
sqlite-analyzer = lowPrio (callPackage ../development/libraries/sqlite/analyzer.nix { });
@@ -18227,6 +18228,7 @@ in
libpng = libpng_apng;
python = python2;
gnused = gnused_422;
sqlite = sqlite_3_30;
inherit (darwin.apple_sdk.frameworks) CoreMedia ExceptionHandling
Kerberos AVFoundation MediaToolbox
CoreLocation Foundation AddressBook;