rhine: init at 0.4.1, river-channel: init at 0.4.1 (#563730)

pkgs/by-name/rh/rhine/package.nix

@@ -0,0 +1,83 @@
+{
+  dbus,
+  fetchFromCodeberg,
+  lib,
+  libxkbcommon,
+  nix-update-script,
+  pkg-config,
+  river,
+  river-channel,
+  stdenv,
+  wayland,
+  wayland-protocols,
+  wayland-scanner,
+  zig_0_16,
+  withStripDebug ? true,
+}:
+
+let
+  inherit (lib.trivial)
+    boolToString
+    ;
+  zig = zig_0_16;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rhine";
+  version = "0.4.1";
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  src = fetchFromCodeberg {
+    owner = "Sivecano";
+    repo = "rhine";
+    tag = finalAttrs.version;
+    hash = "sha256-wJPwooj1f1xb+DhnxaF6iDD9NASlgQZ1OPgrtCCXtoQ=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    zig
+  ];
+
+  buildInputs = [
+    libxkbcommon
+    wayland
+    # wayland-scanner must be placed in buildInputs in order for build to succeed
+    wayland-scanner
+    river
+    wayland-protocols
+    river-channel
+    dbus
+  ];
+
+  zigDeps = zig.fetchDeps {
+    inherit (finalAttrs) src pname version;
+    hash = "sha256-nePZDV4TnFdI20cvhmyRoNi4OG33f+bvRPOE1xbrG4E=";
+  };
+
+  zigBuildFlags = [
+    "-Dstrip=${boolToString withStripDebug}"
+  ];
+
+  postConfigure = ''
+    ln -s ${finalAttrs.zigDeps} $ZIG_GLOBAL_CACHE_DIR/p
+  '';
+
+  passthru = {
+    providedSessions = [ "rhine" ];
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    homepage = "https://codeberg.org/sivecano/rhine";
+    description = "window manager for river supporting multiple layouts and awesome animations";
+    maintainers = with lib.maintainers; [
+      OulipianSummer
+      atemu
+    ];
+    license = with lib.licenses; [
+      gpl3Only
+    ];
+    mainProgram = "rhine";
+  };
+})

pkgs/by-name/ri/river-channel/package.nix

@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  zig,
+  pkg-config,
+  wayland-scanner,
+  wayland-protocols,
+  wayland,
+  river,
+  libxkbcommon,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "river-channel";
+  version = "0.4.1";
+  __structuredAttrs = true;
+  strictDeps = true;
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "Sivecano";
+    repo = "channel";
+    tag = finalAttrs.version;
+    hash = "sha256-AIP5SO7p2Z8fYeLSoIliSya2fQALV1xkkYfIRdHY6TQ=";
+  };
+
+  nativeBuildInputs = [
+    zig
+    pkg-config
+  ];
+
+  buildInputs = [
+    # wayland-scanner must be placed in buildInputs in order for build to succeed
+    wayland-scanner
+    wayland-protocols
+    wayland
+    river
+    libxkbcommon
+  ];
+
+  zigDeps = zig.fetchDeps {
+    inherit (finalAttrs) src pname version;
+    hash = "sha256-RD/0GMhzh26P2Hxb/5ksLC4kvLNOG489ojbFwwscIr8=";
+  };
+
+  postConfigure = ''
+    ln -s ${finalAttrs.zigDeps} $ZIG_GLOBAL_CACHE_DIR/p
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Input config for river";
+    homepage = "https://codeberg.org/Sivecano/channel";
+    changelog = "https://codeberg.org/Sivecano/channel/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [
+      OulipianSummer
+      atemu
+    ];
+    mainProgram = "channel";
+  };
+})