antigravity-acp: init at 1.0.0

2026-10-03 21:40:12 +00:00 · 2026-08-30 12:13:04 +03:30
parent 088da7f080
commit 0cded46f11
1 changed files with 76 additions and 0 deletions
--- a/pkgs/by-name/an/antigravity-acp/package.nix
+++ b/pkgs/by-name/an/antigravity-acp/package.nix
@@ -0,0 +1,76 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  unzip,
+  autoPatchelfHook,
+}:
+let
+  sources = {
+    x86_64-linux = {
+      url = "https://dl.google.com/agy-extensions/releases/linux/agy-acp-server-agy_acp_server_20260818_01_RC01-linux-x86_64.zip";
+      hash = "sha256-zj8JYoV1slSXz1o8GdBztJrLgPHasf+FkpGenJuHmeE="; # Run `nix store prefetch-file <url>`
+    };
+    aarch64-linux = {
+      url = "https://dl.google.com/agy-extensions/releases/linux/agy-acp-server-agy_acp_server_20260818_01_RC01-linux-arm64.zip";
+      hash = "sha256-cPzaxwaE3mD3oOsW6kl9bMRJhyhCDwYOCFDPyakym0A=";
+    };
+    aarch64-darwin = {
+      url = "https://dl.google.com/agy-extensions/releases/macos/agy-acp-server-agy_acp_server_20260818_01_RC01-darwin-arm64.zip";
+      hash = "sha256-8SLKfnAwon+WSdpM8afYDhLEjF9hGP81r/w01Wy/g90=";
+    };
+  };
+
+  srcInfo =
+    sources.${stdenv.hostPlatform.system}
+      or (throw "Unsupported platform for antigravity-acp: ${stdenv.hostPlatform.system}");
+in
+stdenv.mkDerivation {
+  pname = "antigravity-acp";
+  version = "1.0.0";
+
+  src = fetchurl {
+    inherit (srcInfo) url hash;
+  };
+
+  nativeBuildInputs = [
+    unzip
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux [
+    autoPatchelfHook
+  ];
+
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  sourceRoot = ".";
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    install -m755 agy_acp_server.par $out/bin/agy_acp_server.par
+    install -m555 localharness_external $out/bin/localharness_external
+
+    ln -s $out/bin/agy_acp_server.par $out/bin/agy_acp_server
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Google's AI coding agent. Official ACP server powered by Antigravity";
+    homepage = "https://antigravity.google/docs/ide/extensions";
+    license = lib.licenses.unfree;
+    maintainers = [
+      lib.maintainers.aliheidary1381
+      lib.maintainers.johnrtitor
+    ];
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "aarch64-darwin"
+    ];
+    mainProgram = "agy_acp_server";
+  };
+}