python3Packages.djangorestframework_3_17: init at 3.17.1

pkgs/development/python-modules/djangorestframework/3_17.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonOlder,
+
+  # build-system
+  setuptools,
+
+  # dependencies
+  django,
+
+  # optional-dependencies
+  coreapi,
+  coreschema,
+  django-guardian,
+  inflection,
+  psycopg2,
+  pygments,
+  pyyaml,
+
+  # tests
+  pytestCheckHook,
+  pytest-django,
+  pytz,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "djangorestframework";
+  version = "3.17.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "encode";
+    repo = "django-rest-framework";
+    tag = finalAttrs.version;
+    hash = "sha256-hDAtICtVFeEXRgR5Shb0IdVlLkpf/TBDWw+2cOLJTfw=";
+  };
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    django
+  ];
+
+  optional-dependencies = {
+    complete = [
+      coreapi
+      coreschema
+      django-guardian
+      inflection
+      psycopg2
+      pygments
+      pyyaml
+    ];
+  };
+
+  nativeCheckInputs = [
+    pytest-django
+    pytestCheckHook
+    pytz
+  ]
+  ++ finalAttrs.passthru.optional-dependencies.complete;
+
+  disabledTests = [
+    # https://github.com/encode/django-rest-framework/issues/9422
+    "test_urlpatterns"
+  ];
+
+  pythonImportsCheck = [ "rest_framework" ];
+
+  meta = {
+    changelog = "https://github.com/encode/django-rest-framework/releases/tag/${finalAttrs.src.tag}";
+    description = "Web APIs for Django, made easy";
+    homepage = "https://www.django-rest-framework.org/";
+    license = lib.licenses.bsd2;
+  };
+})

pkgs/top-level/python-packages.nix

@@ -4998,6 +4998,10 @@ self: super: with self; {
 
   djangorestframework-stubs = callPackage ../development/python-modules/djangorestframework-stubs { };
 
+  djangorestframework_3_17 =
+    callPackage ../development/python-modules/djangorestframework/3_17.nix
+      { };
+
   djangosaml2 = callPackage ../development/python-modules/djangosaml2 { };
 
   djmail = callPackage ../development/python-modules/djmail { };