rumdl: init at 0.0.156 (#446292)

pkgs/by-name/ru/rumdl/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "rumdl";
+  version = "0.0.156";
+
+  src = fetchFromGitHub {
+    owner = "rvben";
+    repo = "rumdl";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-yHOfrX3iOq1oGwHtHchMyQblqLXreoUKLBTpxxh2FEE=";
+  };
+
+  cargoHash = "sha256-U8kb3fQjA3Prrpn1KmhsQl4S0hvhcY+5qlqT5ovbUZE=";
+
+  cargoBuildFlags = [
+    "--bin=rumdl"
+  ];
+
+  __darwinAllowLocalNetworking = true; # required for LSP tests
+
+  useNextest = true;
+
+  cargoTestFlags = [
+    "--profile ci"
+  ];
+
+  checkFlags = [
+    # Skip Windows tests
+    "--skip comprehensive_windows_tests"
+    "--skip windows_vscode_tests"
+  ];
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  versionCheckProgramArg = "--version";
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Markdown linter and formatter";
+    longDescription = ''
+      rumdl is a high-performance Markdown linter and formatter
+      that helps ensure consistency and best practices in your Markdown files.
+    '';
+    homepage = "https://github.com/rvben/rumdl";
+    changelog = "https://github.com/rvben/rumdl/blob/v${finalAttrs.version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      kachick
+      hasnep
+    ];
+    mainProgram = "rumdl";
+    platforms = with lib.platforms; unix ++ windows;
+  };
+})