scenefx{,_0_4,_0_5}: drop 0_4, move to pkgs/by-name, make 0_5 an alias

after the swayfx update, 0_4 is not needed anymore

thus we can also drop the 0_5 alias and move the package back to
pkgs/by-name

next time a package needs an old version, do the version override in the
package that needs it instead of moving scenefx out of pkgs/by-name

pkgs/by-name/ma/mango/package.nix

@@ -19,7 +19,7 @@
   enableXWayland ? true,
   meson,
   ninja,
-  scenefx_0_5,
+  scenefx,
   wlroots_0_20,
   libGL,
 }:
@@ -54,7 +54,7 @@ stdenv.mkDerivation (finalAttrs: {
     wayland
     wayland-protocols
     wlroots_0_20
-    scenefx_0_5
+    scenefx
     libGL
   ]
   ++ lib.optionals enableXWayland [

pkgs/by-name/sc/scenefx/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  wlroots_0_20,
+  scdoc,
+  pkg-config,
+  wayland,
+  libdrm,
+  libxkbcommon,
+  pixman,
+  wayland-protocols,
+  libGL,
+  libgbm,
+  libxcb,
+  libxcb-wm,
+  lcms2,
+  validatePkgConfig,
+  testers,
+  wayland-scanner,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  __structuredAttrs = true;
+  pname = "scenefx";
+  version = "0.5";
+
+  src = fetchFromGitHub {
+    owner = "wlrfx";
+    repo = "scenefx";
+    tag = finalAttrs.version;
+    hash = "sha256-vUjLG6eubEhJJVa9LPygIcVmNoHwYbSUTJcWEcbxnU4=";
+  };
+
+  strictDeps = true;
+  depsBuildBuild = [ pkg-config ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    scdoc
+    validatePkgConfig
+    wayland-scanner
+  ];
+
+  buildInputs = [
+    libdrm
+    libGL
+    libxkbcommon
+    libgbm
+    libxcb
+    libxcb-wm
+    pixman
+    wayland
+    wayland-protocols
+    wlroots_0_20
+    lcms2
+  ];
+
+  passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+
+  meta = {
+    changelog = "${finalAttrs.src.meta.homepage}/releases/tag/${finalAttrs.version}";
+    description = "Drop-in replacement for the wlroots scene API that allows wayland compositors to render surfaces with eye-candy effects";
+    homepage = finalAttrs.src.meta.homepage;
+    license = lib.licenses.mit;
+    mainProgram = "scenefx";
+    maintainers = with lib.maintainers; [
+      swarsel
+      yvnth
+    ];
+    pkgConfigModules = [ "scenefx-${lib.versions.majorMinor finalAttrs.version}" ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/sw/swayfx-unwrapped/package.nix

@@ -22,7 +22,7 @@
   json_c,
   libevdev,
   scdoc,
-  scenefx_0_5,
+  scenefx,
   wayland-scanner,
   libxcb-wm,
   wlroots_0_20,
@@ -96,7 +96,7 @@ stdenv.mkDerivation (finalAttrs: {
     libxkbcommon
     pango
     pcre2
-    scenefx_0_5
+    scenefx
     wayland
     wayland-protocols
     (wlroots_0_20.override { inherit (finalAttrs) enableXWayland; })

pkgs/development/libraries/scenefx/default.nix

@@ -1,106 +0,0 @@
-{
-  lib,
-  stdenv,
-  fetchFromGitHub,
-  meson,
-  ninja,
-  wlroots_0_19,
-  wlroots_0_20,
-  scdoc,
-  pkg-config,
-  wayland,
-  libdrm,
-  libxkbcommon,
-  pixman,
-  wayland-protocols,
-  libGL,
-  libgbm,
-  libxcb,
-  libxcb-wm,
-  lcms2,
-  validatePkgConfig,
-  testers,
-  wayland-scanner,
-}:
-
-let
-  generic =
-    {
-      version,
-      hash,
-      wlroots,
-      extraBuildInputs ? [ ],
-    }:
-    stdenv.mkDerivation (finalAttrs: {
-      __structuredAttrs = true;
-      pname = "scenefx";
-      inherit version;
-
-      src = fetchFromGitHub {
-        owner = "wlrfx";
-        repo = "scenefx";
-        tag = finalAttrs.version;
-        inherit hash;
-      };
-
-      strictDeps = true;
-      depsBuildBuild = [ pkg-config ];
-
-      nativeBuildInputs = [
-        meson
-        ninja
-        pkg-config
-        scdoc
-        validatePkgConfig
-        wayland-scanner
-      ];
-
-      buildInputs = [
-        libdrm
-        libGL
-        libxkbcommon
-        libgbm
-        libxcb
-        libxcb-wm
-        pixman
-        wayland
-        wayland-protocols
-        wlroots
-      ]
-      ++ extraBuildInputs;
-
-      passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
-
-      meta = {
-        description = "Drop-in replacement for the wlroots scene API that allows wayland compositors to render surfaces with eye-candy effects";
-        homepage = "https://github.com/wlrfx/scenefx";
-        changelog = "https://github.com/wlrfx/scenefx/releases/tag/${finalAttrs.version}";
-        license = lib.licenses.mit;
-        maintainers = with lib.maintainers; [
-          swarsel
-          yvnth
-        ];
-
-        mainProgram = "scenefx";
-        pkgConfigModules = [ "scenefx-${lib.versions.majorMinor finalAttrs.version}" ];
-        platforms = lib.platforms.all;
-      };
-    });
-
-in
-rec {
-  scenefx_0_4 = generic {
-    version = "0.4.1";
-    hash = "sha256-XD5EcquaHBg5spsN06fPHAjVCb1vOMM7oxmjZZ/PxIE=";
-    wlroots = wlroots_0_19;
-  };
-
-  scenefx_0_5 = generic {
-    version = "0.5";
-    hash = "sha256-vUjLG6eubEhJJVa9LPygIcVmNoHwYbSUTJcWEcbxnU4=";
-    wlroots = wlroots_0_20;
-    extraBuildInputs = [ lcms2 ];
-  };
-
-  scenefx = scenefx_0_5;
-}

pkgs/top-level/aliases.nix

@@ -2179,6 +2179,8 @@ mapAliases {
   sawfish = throw "'sawfish' has been removed as it depended on the deprecated GTK2 engine."; # Added 2026-08-03
   scantailor = throw "'scantailor' has been renamed to/replaced by 'scantailor-advanced'"; # Converted to throw 2025-10-27
   scaphandre = throw "'scaphandre' was broken with no upstream progress since February 2025"; # Added 2026-06-14
+  scenefx_0_4 = throw "'scenefx_0_4' has been removed in favor of newer versions."; # Added 2026-08-14
+  scenefx_0_5 = scenefx; # Added 2026-08-14
   scitoken-cpp = throw "'scitoken-cpp' has been renamed to/replaced by 'scitokens-cpp'"; # Converted to throw 2025-10-27
   scudcloud = throw "'scudcloud' has been removed as it was archived by upstream"; # Added 2025-07-24
   SDL2_classic = throw "'SDL2_classic' has been removed. Consider upgrading to 'sdl2-compat', also available as 'SDL2'."; # Added 2025-05-20

pkgs/top-level/all-packages.nix

@@ -8781,12 +8781,6 @@ with pkgs;
     wlroots_0_20
     ;
 
-  inherit (callPackages ../development/libraries/scenefx { })
-    scenefx_0_4
-    scenefx_0_5
-    scenefx
-    ;
-
   sway-contrib = recurseIntoAttrs (callPackages ../applications/misc/sway-contrib { });
 
   ikiwiki = callPackage ../applications/misc/ikiwiki {