clippy-copy: init at 1.6.9 (#518816)

maintainers/maintainer-list.nix

@@ -16483,6 +16483,12 @@
     githubId = 8094643;
     keys = [ { fingerprint = "BAA9 7711 58CA D457 B4AE  8B06 8188 423D 2FA2 0A65"; } ];
   };
+  m4r1vs = {
+    email = "marius.niveri@gmail.com";
+    name = "Marius Niveri";
+    github = "m4r1vs";
+    githubId = 26097311;
+  };
   m7medvision = {
     name = "Mohammed";
     github = "m7medVision";

pkgs/by-name/cl/clippy-copy/package.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "clippy-copy";
+  version = "1.6.9";
+
+  src = fetchFromGitHub {
+    owner = "neilberkman";
+    repo = "clippy";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-8OdT+R4dvJCLhelIAsAgVoWGGwmWueTsiJFpCm1uQEc=";
+  };
+
+  vendorHash = "sha256-7do+KgoiIocS+mq2hsgv3NOd+TjMl2I9ew2Emx3/Bbg=";
+
+  ldflags = [
+    "-s"
+    "-X=github.com/neilberkman/clippy/cmd/internal/common.Version=${finalAttrs.version}"
+    "-X=github.com/neilberkman/clippy/cmd/internal/common.Commit=${finalAttrs.src.tag}"
+    "-X=github.com/neilberkman/clippy/cmd/internal/common.Date=1970-01-01T00:00:00Z"
+  ];
+
+  # Tests require access to the system clipboard (unavailable in sandbox)
+  doCheck = false;
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+
+  passthru.updateScript = nix-update-script { };
+
+  __structuredAttrs = true;
+
+  meta = {
+    description = "Clipboard tool supporting both text and binary files";
+    homepage = "https://github.com/neilberkman/clippy";
+    changelog = "https://github.com/neilberkman/clippy/blob/${finalAttrs.src.tag}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ m4r1vs ];
+    mainProgram = "clippy";
+    platforms = lib.platforms.darwin;
+  };
+})