python313Packages.unstructured-client: init at 0.31.5

pkgs/development/python-modules/unstructured-client/default.nix

@@ -0,0 +1,75 @@
+{
+  aiofiles,
+  buildPythonPackage,
+  cryptography,
+  deepdiff,
+  eval-type-backport,
+  fetchFromGitHub,
+  httpx,
+  lib,
+  nest-asyncio,
+  poetry-core,
+  pydantic,
+  pypdf,
+  pytest-asyncio,
+  pytestCheckHook,
+  python,
+  python-dateutil,
+  requests-toolbelt,
+  typing-inspection,
+}:
+
+buildPythonPackage rec {
+  pname = "unstructured-client";
+  version = "0.31.5";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "Unstructured-IO";
+    repo = "unstructured-python-client";
+    tag = "v${version}";
+    hash = "sha256-b5Hnp3XKuuGUWEFhQzTArUUWbsZ2+Q2Iz+3+WjMn4XU=";
+  };
+
+  preBuild = ''
+    ${python.interpreter} scripts/prepare_readme.py
+  '';
+
+  build-system = [ poetry-core ];
+
+  dependencies = [
+    aiofiles
+    cryptography
+    eval-type-backport
+    httpx
+    nest-asyncio
+    pydantic
+    pypdf
+    python-dateutil
+    requests-toolbelt
+    typing-inspection
+  ];
+
+  pythonImportsCheck = [ "unstructured_client" ];
+
+  nativeCheckInputs = [
+    deepdiff
+    pytest-asyncio
+    pytestCheckHook
+  ];
+
+  pytestFlagsArray = [
+    # see test-unit in Makefile
+    "_test_unstructured_client"
+    "-k"
+    "unit"
+  ];
+
+  meta = {
+    changelog = "https://github.com/Unstructured-IO/unstructured-python-client/blob/${src.tag}/RELEASES.md";
+    description = "Python Client SDK for Unstructured API";
+    homepage = "https://github.com/Unstructured-IO/unstructured-python-client";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ dotlambda ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -18554,6 +18554,8 @@ self: super: with self; {
 
   unstructured-api-tools = callPackage ../development/python-modules/unstructured-api-tools { };
 
+  unstructured-client = callPackage ../development/python-modules/unstructured-client { };
+
   unstructured-inference = callPackage ../development/python-modules/unstructured-inference { };
 
   untangle = callPackage ../development/python-modules/untangle { };