mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-10-04 14:00:04 +00:00
b1371e26ae
using the displaylink module currently fails with `systemd.enableStrictShellChecks = true;`. there are two warnings: - `read` without `-r` can technically mangle backslashes, as it acts as an escape character by default. as far as we can tell, this shouldn't cause problems, but it seems like a harmless and technically-correct fix. - `SUSPEND_RESULT` is unused. as far as i can tell, this indeed seems to be the case, so this makes sense to remove.
82 lines
1.9 KiB
Nix
82 lines
1.9 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
|
|
enabled = lib.elem "displaylink" config.services.xserver.videoDrivers;
|
|
|
|
evdi = config.boot.kernelPackages.evdi;
|
|
|
|
displaylink = pkgs.displaylink.override {
|
|
inherit evdi;
|
|
};
|
|
|
|
in
|
|
|
|
{
|
|
|
|
config = lib.mkIf enabled {
|
|
|
|
boot.extraModulePackages = [ evdi ];
|
|
boot.kernelModules = [ "evdi" ];
|
|
|
|
services.xserver.externallyConfiguredDrivers = [ "displaylink" ];
|
|
|
|
environment.etc."X11/xorg.conf.d/40-displaylink.conf".text = ''
|
|
Section "OutputClass"
|
|
Identifier "DisplayLink"
|
|
MatchDriver "evdi"
|
|
Driver "modesetting"
|
|
Option "TearFree" "true"
|
|
Option "AccelMethod" "none"
|
|
EndSection
|
|
'';
|
|
|
|
# make the device available
|
|
services.xserver.displayManager.sessionCommands = ''
|
|
${lib.getBin pkgs.xrandr}/bin/xrandr --setprovideroutputsource 1 0
|
|
'';
|
|
|
|
# Those are taken from displaylink-installer.sh and from Arch Linux AUR package.
|
|
|
|
services.udev.packages = [ displaylink ];
|
|
|
|
powerManagement.powerDownCommands = ''
|
|
#flush any bytes in pipe
|
|
while read -r -n 1 -t 1 < /tmp/PmMessagesPort_out; do : ; done;
|
|
|
|
#suspend DisplayLinkManager
|
|
echo "S" > /tmp/PmMessagesPort_in
|
|
|
|
#wait until suspend of DisplayLinkManager finish
|
|
if [ -f /tmp/PmMessagesPort_out ]; then
|
|
#wait until suspend of DisplayLinkManager finish
|
|
read -r -n 1 -t 10 < /tmp/PmMessagesPort_out
|
|
fi
|
|
'';
|
|
|
|
powerManagement.resumeCommands = ''
|
|
#resume DisplayLinkManager
|
|
echo "R" > /tmp/PmMessagesPort_in
|
|
'';
|
|
|
|
systemd.services.dlm = {
|
|
description = "DisplayLink Manager Service";
|
|
after = [ "display-manager.service" ];
|
|
conflicts = [ "getty@tty7.service" ];
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${displaylink}/bin/DisplayLinkManager";
|
|
Restart = "always";
|
|
RestartSec = 5;
|
|
LogsDirectory = "displaylink";
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
}
|